4

我是第一次使用 DBpedia。我想下载人员数据集中的所有人员以及 commonName、nationality、birthDate 和 knownFor 的属性（我最终会使用我认为的某种脚本语言将其粘贴到 Excel 电子表格中）。

这是我第一次尝试查询来完成这项工作，但是它不起作用。我尝试将它与我在互联网上看到的其他代码拼凑在一起。有谁知道如何解决这一问题？谢谢

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>        
PREFIX type: <http://dbpedia.org/class/yago/>
PREFIX prop: <http://dbpedia.org/property/> 

SELECT ?person ?commonName ?nationality ?knownFor ? birthDate
WHERE {
    ?person a type:Person .
    ?person prop:commonName ?commonNameFilter(lang(?commonName) = 'en') .
    ?person prop:nationality ?nationality(lang(?nationality) = 'en') .
    ?person prop:knownFor ?knownFor(lang(?knownFor) = 'en') .
    ?person prop:birthDate ?birthDate .
}

编辑：新版本的代码：返回 COMMONNAME（带有非英语重复项）。仍然缺少其他属性。

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>        
PREFIX type: <http://dbpedia.org/class/yago/>
PREFIX prop: <http://dbpedia.org/ontology/>

SELECT DISTINCT * WHERE {
    ?person a dbpedia-owl:Person ;  
              dbpedia-owl:commonName ?commonName . FILTER(lang(?commonName) = 'en')
}
LIMIT 30
4

2 回答 2

6

首先，您的查询有很多语法问题：

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>        
PREFIX type: <http://dbpedia.org/class/yago/>
PREFIX prop: <http://dbpedia.org/property/> 
            ^ you probably want to use the dbpedia-owl properties which are 
            # in <http://dbpedia.org/ontology/>
SELECT ?person ?commonName ?nationality ?knownFor ? birthDate
                                                   ^ space between ? and varname
WHERE {
    ?person a type:Person .
    ?person prop:commonName ?commonNameFilter(lang(?commonName) = 'en') .
                                       ^ This needs to be "?commonName . FILTER(..."
                                       # and the same thing applies to your other 
                                       # filters
    ?person prop:nationality ?nationality(lang(?nationality) = 'en') .
    ?person prop:knownFor ?knownFor(lang(?knownFor) = 'en') .
    ?person prop:birthDate ?birthDate .
}

以增量方式构建其中一些查询更容易，因为这样您就可以找出某些资源实际具有的属性，然后您可以进一步扩展您的查询。公共端点有许多预定义的命名空间，使用这些命名空间会让其他人更容易阅读您的查询。因此，您可以从询问人员开始：

SELECT * WHERE {
    ?person a dbpedia-owl:Person .
}
LIMIT 10

SPARQL 结果

看到它正在工作，您可以查看一些返回的实例并查看它们是否具有dbpedia-owl:commonName属性，然后扩展查询：

SELECT * WHERE {
    ?person a dbpedia-owl:Person ;  
              dbpedia-owl:commonName ?commonName .
}
LIMIT 10

SPARQL 结果

dbpedia-owl:birthDate用属性扩展它很容易。我没有看到关于我查看过nationality的实例的谓词，所以我不确定您基于什么进行国籍查询。虽然我看到了该knownFor属性的一些用途，但在很多情况下我都没有看到它，因此如果您将其设为必需属性，您将排除很多人。不过，从长远来看，这种增量方法可能会对您有所帮助。

查找属性

虽然可浏览本体提供了一种查找类的好方法，但我不确定是否有这种查找属性的好方法。但是，您可以以蛮力的方式做某事。例如，要查找实际用于Persons 的所有属性，您可以运行如下查询。（注意：这个查询需要一段时间来执行，所以如果你使用它，你可能应该下载结果。）

select distinct ?p where {
  [] a dbpedia-owl:Person ;
     ?p [] .
}

SPARQL 结果

我会注意到dbpedia-owl:nationality 确实出现在该列表中。

要获取所有内容的所有属性，您可以下载本体，然后运行如下查询：

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix owl: <http://www.w3.org/2002/07/owl#>
select * where { 
  { ?p a owl:ObjectProperty }
  UNION 
  { ?p a owl:DatatypeProperty }
}

我使用 Jena 的 ARQ 在本地运行它：

$ arq --query properties.sparql --data dbpedia_3.8.owl
----------------------------------------------------------------------------
| p                                                                        |
============================================================================
| <http://dbpedia.org/ontology/regionServed>                               |
| <http://dbpedia.org/ontology/coachedTeam>                                |
| <http://dbpedia.org/ontology/legalForm>                                  |
| <http://dbpedia.org/ontology/goldenCalfAward>                            |
| <http://dbpedia.org/ontology/composer>                                   |
| <http://dbpedia.org/ontology/owningOrganisation>                         |
| <http://dbpedia.org/ontology/branchFrom>                                 |
| <http://dbpedia.org/ontology/iso6393Code>                                |
...
| <http://dbpedia.org/ontology/classification>                             |
| <http://dbpedia.org/ontology/bgafdId>                                    |
| <http://dbpedia.org/ontology/currencyCode>                               |
| <http://dbpedia.org/ontology/onChromosome>                               |
| <http://dbpedia.org/ontology/course>                                     |
| <http://dbpedia.org/ontology/frequentlyUpdated>                          |
| <http://dbpedia.org/ontology/distance>                                   |
| <http://dbpedia.org/ontology/volume>                                     |
| <http://dbpedia.org/ontology/description>                                |
----------------------------------------------------------------------------

这不会提供rdfs:domainand rdfs:range，但你也可以要求这些，或者只要求那些属性rdfs:range dbpedia-owl:Person（但请注意，这不会得到所有可以使用的属性Person，因为范围可能或多或少是特定的）：

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix owl: <http://www.w3.org/2002/07/owl#>
prefix dbpedia-owl: <http://dbpedia.org/ontology/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>

select ?p ?range where { 
  { ?p a owl:ObjectProperty }
  UNION 
  { ?p a owl:DatatypeProperty }

  ?p rdfs:domain dbpedia-owl:Person ; rdfs:range ?range .
}


$ arq --query properties.sparql --data dbpedia_3.8.owl | head
--------------------------------------------------------------------------------------------------------
| p                                           | range                                                  |
========================================================================================================
| dbpedia-owl:restingPlacePosition            | <http://www.w3.org/2003/01/geo/wgs84_pos#SpatialThing> |
| dbpedia-owl:opponent                        | dbpedia-owl:Person                                     |
| dbpedia-owl:employer                        | dbpedia-owl:Organisation                               |
| dbpedia-owl:hometown                        | dbpedia-owl:Settlement                                 |
| dbpedia-owl:militaryBranch                  | dbpedia-owl:MilitaryUnit                               |
| dbpedia-owl:school                          | dbpedia-owl:EducationalInstitution                     |
| dbpedia-owl:ethnicity                       | dbpedia-owl:EthnicGroup                                |
...
| dbpedia-owl:sex                             | xsd:string                                             |
| dbpedia-owl:hipSize                         | xsd:double                                             |
| dbpedia-owl:individualisedPnd               | xsd:nonNegativeInteger                                 |
| dbpedia-owl:weddingParentsDate              | xsd:date                                               |
| dbpedia-owl:birthName                       | xsd:string                                             |
| dbpedia-owl:networth                        | xsd:double                                             |
| dbpedia-owl:birthYear                       | xsd:gYear                                              |
| dbpedia-owl:bustSize                        | xsd:double                                             |
| dbpedia-owl:description                     | xsd:string                                             |
--------------------------------------------------------------------------------------------------------
于 2013-07-15T19:48:34.080 回答
2

我还不太擅长 SPARQL，但我确实在这里看到了一些语法问题。我将查询重写为如下所示：

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>        
PREFIX type: <http://dbpedia.org/class/yago/>
PREFIX prop: <http://dbpedia.org/property/>
SELECT ?person, ?commonName, ?nationality, ?knownFor, ?birthDate
WHERE {
    ?person a type:Person .
    ?person prop:commonName ?commonName .
    FILTER (lang(?commonName) = 'en') .
    ?person prop:nationality ?nationality .
    FILTER (lang(?nationality) = 'en') .
    ?person prop:knownFor ?knownFor .
    FILTER (lang(?knownFor) = 'en') .
    ?person prop:birthDate ?birthDate .
}

现在它至少运行查询没有错误。但我没有看到结果。不知道为什么

于 2013-07-15T18:26:47.443 回答