1

我找不到解决问题的有效方法。当它们在文档中的特定位置时，我需要将具有相同名称的两个元素合并为一个：标签 hi 当它们之间保持 lb break='no'。我怎样才能做到这一点？xml代码是：

<p>
 <lb n="28"/> Lorem ipsum dolor sit
 <lb n="29"/> amet, consectetur, <hi rend="u">adi</hi>
 <lb n="30" break="no"/><hi rend="u">pisci</hi> elit...
</p>

我将它转换为没有换行符的浮动文本，并且由于那里有一个连字符，我需要将两个元素合并为一个。现在我总是在他们之间产生空白。

<p>Lorem ipsum dolor sit amet, consectetur <span class="u">adipisici</span> elit...</p>

非常感谢！

4

1 回答 1

1

假设您可以使用像 Saxon 9 或 XmlPrime 这样的 XSLT 2.0 处理器

<xsl:stylesheet
  version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs">

<xsl:template match="p">
  <xsl:copy>
    <xsl:for-each-group select="node() except text()[not(normalize-space())]"
      group-adjacent="self::hi or self::lb[@break = 'no']">
      <xsl:choose>
        <xsl:when test="current-grouping-key()">
          <span class="{current-group()[self::hi][1]/@rend}">
            <xsl:apply-templates select="current-group()/node()"/>
          </span>
        </xsl:when>
        <xsl:otherwise>
          <xsl:apply-templates select="current-group()"/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:for-each-group>
  </xsl:copy>
</xsl:template>

</xsl:stylesheet>

改造

<p>
 <lb n="28"/> Lorem ipsum dolor sit
 <lb n="29"/> amet, consectetur, <hi rend="u">adi</hi>
 <lb n="30" break="no"/><hi rend="u">pisci</hi> elit...
</p>

进入

<p> Lorem ipsum dolor sit
  amet, consectetur, <span class="u">adipisci</span> elit...
</p>
于 2013-07-15T11:57:01.710 回答