0

我遇到了一个似乎无法修复的错误。我想我知道发生了什么，但我不确定是否能够修复它。我不断收到错误

“TypeError：错误 #2007：参数 hitTestObject 必须为非空。

在 flash.display::DisplayObject/_hitTest()

在 flash.display::DisplayObject/hitTestObject()"

基本上我会在我的游戏中发动攻击。它击中了一个敌人，他被杀死了。但是，他死时有一个动画，需要几秒钟。似乎如果我在他的动画期间再次发动攻击，我的攻击会立即给出这个错误（也就是说，在击打任何东西之前）。动画结束后，一切又恢复正常。此外，在我放入此动画之前，游戏运行良好 100%。

这是我的文档类

package com.classes 
{
    import flash.display.MovieClip;
    import flash.display.Stage;
    import flash.events.Event;

    public class DocumentClass extends MovieClip
    {

        // we need to keep track of our enemies.
        public static var enemyList1:Array = new Array();
        // moved stickobject1 to a class variable.
        private var stickobject1:Stickman2;

        public function DocumentClass() : void
        {
            //removed the var stickobject1:Stickman2 because we declared it above.
            var bg1:background1 = new background1();
            stage.addChild(bg1);

            stickobject1 = new Stickman2(stage);
            stage.addChild(stickobject1);

            stickobject1.x=50;
            stickobject1.y=300;

            //running a loop now.... so we can keep creating enemies randomly.
            addEventListener(Event.ENTER_FRAME, loop, false, 0, true);

        }

        //our loop function
        private function loop(e:Event) : void
        {
            //run if condition is met.
            if (Math.floor(Math.random() * 90) == 5)
            {
                //create our enemyObj1 
                var enemyObj1:Enemy1 = new Enemy1(stage, stickobject1);

                //listen for enemyObj1 being removed from stage
                enemyObj1.addEventListener(Event.REMOVED_FROM_STAGE, removeEnemyObj1, false, 0, true);

                //add our enemyObj1 to the enemyList1
                enemyList1.push(enemyObj1);

                stage.addChild(enemyObj1);
            }   
        }

        private function removeEnemyObj1(e:Event)
        {
            enemyList1.splice(enemyList1.indexOf(e.currentTarget), 1);
        }


    }

}

这是我的attack1课

package com.classes {

    import flash.display.MovieClip;
    import flash.display.Stage;
    import com.senocular.utils.KeyObject;
    import flash.ui.Keyboard;
    import flash.events.Event;


    public class attack1 extends MovieClip {


        private var stageRef:Stage;
        private var bulletSpeed:Number = 16;

        public function attack1 (stageRef:Stage, x:Number, y:Number) : void
        {
            this.stageRef = stageRef;
            this.x = x;
            this.y = y;

            addEventListener(Event.ENTER_FRAME, loop, false, 0, true);
        }

        private function loop(e:Event) : void
        {
            //move bullet up
            x += bulletSpeed;

            if (x > stageRef.stageWidth) 
                removeSelf();

            for (var i:int = 0; i < DocumentClass.enemyList1.length; i++)
            {
                if (hitTestObject(DocumentClass.enemyList1[i].hit))
                {
                    trace("hitEnemy");
                    removeSelf();
                    DocumentClass.enemyList1[i].takeHit();
                }
            }
        }

        private function removeSelf() : void
        {
            removeEventListener(Event.ENTER_FRAME, loop);

            if (stageRef.contains(this))
                    stageRef.removeChild(this);
        }

    }

}

不要认为您应该需要我的任何其他课程来弄清楚发生了什么，但是如果您这样做，请告诉我！非常感谢 =)

4

2 回答 2

1

您不想对可能已从场景（或从enemyList 数组）中移除的任何对象进行命中测试。添加到 attack1.loop 的 for 循环的额外条件应该可以消除您的错误。更好的解决方法是拼接您删除的项目，因此它们永远不会在循环中进行测试。

断线将使它在子弹被移除后停止尝试击中其他敌人。如果行“DocumentClass.enemyList1[i].takeHit();” 从enemyList1 中删除该项目，您需要确保使用“i--;” 如果您打算遍历其余的敌人，那么也在循环的底部。“i--”或“break”，您可能会在该循环中需要其中之一。

仔细检查您执行删除方法的顺序。有时，最好标记要删除的项目并在单独的循环中删除它们，而不是在同一循环中删除稍后可能需要的项目。

for (var i:int = 0; i < DocumentClass.enemyList1.length; i++){
  if(DocumentClass.enemyList1[i] && DocumentClass.enemyList1[i].hit){
    if (hitTestObject(DocumentClass.enemyList1[i].hit)){
      trace("hitEnemy");
      removeSelf();
      DocumentClass.enemyList1[i].takeHit();
      break;
    }
  }
}
于 2013-07-13T19:47:00.750 回答
0

不是这个问题的正确解决方案。您始终可以在条件语句中执行 != null 。

if(object!=null){
    party.drink();
}
于 2013-07-14T01:23:45.253 回答