html - 通用 XSLT 用于制表 XML

Question

我正在创建一个足够通用的 XSLT，以创建任何输入 XML 数据的名称-值表。

例如。

<root>
    <Field1>value1</Field1>
    <Field2>value2</Field2>
    <Field3>value3</Field3>
</root>

输出应如下所示：

<table>
   <tr>
      <td>Field1</td>
      <td>value1</td>
  </tr>
   <tr>
      <td>Field2</td>
      <td>value2</td>
  </tr>
   <tr>
      <td>Field3</td>
      <td>value3</td>
  </tr>
</table>

我想避免在 XSLT 代码中使用 xml 标记名称，以使其足够通用。不确定这是否可能。任何想法如何去做？

Answer 1

这是来自@ABach 的解决方案的改进，它尝试创建嵌套表：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="/">
    <table>
      <xsl:apply-templates/>
    </table>
  </xsl:template>

  <xsl:template match="*">
    <tr>
      <td>
        <p><xsl:value-of select="name()"/></p>
      </td>
      <td>
        <p><xsl:value-of select="."/></p>
      </td>
    </tr>
  </xsl:template>

  <xsl:template match="*[*]">
    <tr>
      <td>
        <p><xsl:value-of select="name()"/></p>
      </td>
      <td>
        <table>
          <xsl:apply-templates/>
        </table>
      </td>
    </tr>
  </xsl:template>

</xsl:stylesheet>

我没有尝试对混合内容做任何非常聪明的事情。

Answer 2

如果有人正在寻找一种让某些 XML 在浏览器中可读的快速方法，我在 Michael Kay 的出色解决方案中添加了一些 CSS：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>


  <xsl:template match="/">
    <style>
      body {font-family: sans-serif;}
      td {padding: 4px;}
    </style>
    <table>
      <xsl:apply-templates/>
    </table>
  </xsl:template>

  <xsl:template match="*">
    <tr>
      <td style="background-color: #aaa;">
        <p><xsl:value-of select="name()"/></p>
      </td>
      <td style="background-color: #ccc;">
        <p><xsl:value-of select="."/></p>
      </td>
    </tr>
  </xsl:template>

  <xsl:template match="*[*]">
    <tr>
      <td style="border:2px solid #c55; font-size:120%;">
        <p><xsl:value-of select="name()"/></p>
      </td>
      <td style="">
        <table>
          <xsl:apply-templates/>
        </table>
      </td>
    </tr>
  </xsl:template>

</xsl:stylesheet>

Answer 3

这个 XSLT 是通用的、面向推送的，应该可以解决问题：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="/*">
    <table>
      <xsl:apply-templates/>
    </table>
  </xsl:template>

  <xsl:template match="*">
    <tr>
      <td>
        <xsl:value-of select="name()"/>
      </td>
      <td>
        <xsl:apply-templates/>
      </td>
    </tr>
  </xsl:template>

</xsl:stylesheet>

Answer 4

使用xmlstarlet的替代方法：

xmlstarlet select -D -t \
    -o '<table>' \
    -m '/root/*' \
        -o '<tr>' \
        -o '<td>' -c 'name()' -o '</td>' \
        -o '<td>' -c 'text()' -o '</td>' \
        -o '</tr>' \
    -b \
    -o '</table>' \
xmlfile | xmlstarlet unescape | xmlstarlet format -o -s 2

它产生：

<table>
  <tr>
    <td>Field1</td>
    <td>value1</td>
  </tr>
  <tr>
    <td>Field2</td>
    <td>value2</td>
  </tr>
  <tr>
    <td>Field3</td>
    <td>value3</td>
  </tr>
</table>

Answer 5

为上面由 Michael Kay 发起的漂亮解决方案添加属性：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>


  <xsl:template match="/">
    <style>
      body {font-family: sans-serif;}
      td {padding: 4px;}
    </style>
    <table>
      <xsl:apply-templates/>
    </table>
  </xsl:template>

  <xsl:template match="*">
    <tr>
      <td style="background-color: #aaa;">
        <p><xsl:value-of select="name()"/></p>
      </td>
      <td style="background-color: #ccc;">
        <p><xsl:value-of select="."/></p>
      </td>
    </tr>
  </xsl:template>

  <xsl:template match="*[*]">
    <tr>
      <td style="border:2px solid #c55; font-size:120%; font-style:oblique;">
        <p><xsl:value-of select="name()"/></p>
      </td>
    <xsl:for-each select="@*">
        <p>
            <xsl:value-of select="name()" /> : <xsl:value-of select="." />
        </p>
    </xsl:for-each>
      <td style="">
        <table>
          <xsl:apply-templates/>
        </table>
      </td>
    </tr>
  </xsl:template>

</xsl:stylesheet>

玩一点css，它会产生类似下面的东西......将树视图与表格视图结合在一起并不常见......凯先生，尊重！