19

在 SPARQL 中,我们可以做这样的事情

select * where {
    ?s   (_:prop1 | _:prop2)  "some_val" .
    ...
    #use ?s in other patterns
    ?s    ?o    ?p .
}

是否可以对模式的对象部分做同样的事情?如果不可能,有哪些解决方法?

例如:

select * where {
    ?s   _:prop ("v1" | "v2") .
    ...
    #use ?s in other patterns
    ?s    ?o    ?p .
}
4

2 回答 2

30

有几种方法可以做到这一点。最简单和纯粹的 SPARQL 1.0 方法是使用UNION例如

SELECT * WHERE
{
  { ?s _:prop "v1" } UNION { ?s _:prop "v2" }

  # Use ?s in other patterns
}

这可能是最简单的方法,但如果您需要?s对此进行多个约束,很快就会变得笨拙。

第二种方法是IN在子句中使用函数FILTER,这需要 SPARQL 1.1 实现,例如

SELECT * WHERE
{
  ?s _:prop ?value .
  FILTER(?value IN ("v1", "v2"))

  # Use ?s in other patterns
}

这里的问题是,IN如果您有许多替代方案或大量数据可能与?s _:prop ?value

除了- 许多优化器实际上会将第二种方法扩展到第一种方法。

第三种方法是使用VALUES再次需要 SPARQL 1.1 实现的子句:

SELECT * WHERE
{
  VALUES (?value) { ( "v1" ) ( "v2 " ) }
  ?s _:prop ?value .

  # Use ?s in other patterns
}

这可能是最好的选择,因为它可以更好地扩展到许多替代方案(取决于您的 SPARQL 实现),并且可能是最好的读写方式。

于 2013-07-11T18:01:17.443 回答
4

这很好用:

SELECT *
WHERE
{
    VALUES ?value
    {
       "value1"
       "value2"
       "etc"
    }

    ?s ?p ?value
}
于 2015-02-02T03:19:52.710 回答