12

在尝试构建使用 CMake 的项目时，通常有很多开关可以启用/禁用。

您如何存储某些用户所做的构建设置以使构建可在另一台机器上重现？是否有某种导出功能，或者您只是复制构建（缓存）文件夹？

4

2 回答 2

17

有一个选项可以使用 cmake 预加载用于填充缓存文件的脚本

cmake -C <initial-cache>

初始缓存是一个包含以下列方式设置的变量的文件，例如安装前缀：

set(CMAKE_INSTALL_PREFIX "/my/install/prefix" CACHE PATH "")

然后在使用 cmake 填充缓存时传递此文件。很简单，但我不知道，也没有找到好的样品。另外，这是一种独立于平台的方式，而不是编写脚本或批处理文件。

我在生成的源外构建文件夹中的源旁边创建了一个单独的脚本文件夹。我的包含设置的文件存储在那里，供每个要构建的 lib/executable 使用。

您可以将所有设置放入一个单独的文件中，最终只剩下几个调用：

cmake -E make_directory build/somelib
cmake -E chdir build/somelib cmake -C ../../script/cmake/somelib.cmake ../../source/somelib/src
cmake --build build/somelib --target install

很简单，不是吗？

自动生成initial-cache文件：

如果您在 *nix 系统上，您可以在构建目录中运行以下命令：

cmake -N -LA | tail -n+2 | sed -r 's/([A-Za-z_0-9]+):([A-Z]+)=(.*)/set(\1 "\3" CACHE \2 "")/' >cmake-init.txt

在 Windows 上，类似以下cmake脚本的内容应该可以工作：

# list all cache variables
# this should be run in your build dir

set(filename ${CMAKE_ARGV3})
message(STATUS "Writing to ${filename}")
if(NOT filename)
    message(FATAL_ERROR "Must provide an output filename")
    return()
endif()

execute_process(COMMAND "${CMAKE_COMMAND}" "-N" "-LA" OUTPUT_VARIABLE cacheVars)
string(REPLACE "\n" ";" cacheVars ${cacheVars})
file(WRITE ${filename} "")

foreach (variable ${cacheVars})
    string(REGEX REPLACE "([A-Za-z_0-9]+):([A-Z]+)=(.*)$" "set(\\1 \"\\3\" CACHE \\2 \"\")\n" output ${variable})
    if(CMAKE_MATCH_0)
        file(APPEND ${filename} ${output})
    endif()
endforeach()

将其保存到例如，get_cache_vars.cmake然后像这样运行它：

cd <your build-dir>
cmake -P path\to\get_cache_vars.cmake <outputfile.txt>
于 2013-07-11T16:14:25.477 回答
2

在另一台机器上复制它的最好方法是使用 -DSETTING=TRUE/FALSE 参数。

如果您有很多与默认选项不同的选项，您可以使用脚本构建您的 cmake 调用。

前任：

#!/bin/bash
cmake -G "Unix Makefiles \
   -DOPTION1=TRUE
   -DOPTION2=FALSE

将帮助程序 bash 脚本分发到另一台机器。

于 2013-07-11T15:50:32.747 回答