0

我已经使用优秀的ws-lite 库针对合作伙伴的肥皂后端实现了一个小客户端

不幸的是，该库没有提供日志支持 afaik，但我发现这个博客描述了如何使用功能组合进行委托。

现在我想为原始 SoapClient 类上的所有类型的发送方法添加日志记录。我确信使用一些 Groovy 元编程黑魔法是可能的，但我还没有找到任何关于如何做到这一点的示例，而且在动态元编程方面我仍然是一个菜鸟。我想要添加具有相同签名的方法，这些方法在委托给原始方法之前调用日志记录和错误处理。

我还希望仅将它放在一个地方以使我保持干燥，并且在 API 发展时无需适应任何可能的未来重载版本。

SOAPClient 具有发送方法，例如：

public SOAPResponse send(java.util.Map requestParams, groovy.lang.Closure content)
public SOAPResponse send(java.util.Map requestParams, java.lang.String content)
public SOAPResponse send(java.util.Map requestParams, wslite.soap.SOAPVersion soapVersion, java.lang.String content)

现在我可以扩展类，覆盖方法并继续我的生活。但我想知道实现这一目标的 Groovier（和未来证明）方式。

4

2 回答 2

0

我通过查看 tim_yates 提到的示例找到了解决方案。我能找到的最巧妙的方法是在 groovy.runtime.metaclass.wslite.soap 下添加一个 MetaClass，以便按照此处的说明进行自动 MetaClass 注册。

然后该类覆盖了委托给实际soap客户端的invokeMethod。实际上相当不错，但是经常使用的巫毒教有点太多了（就像大多数 AOP 编程恕我直言）

package groovy.runtime.metaclass.wslite.soap

import groovy.transform.ToString
import groovy.util.logging.Log4j
import mycomp.soap.InfrastructureException
import mycomp.soap.HttpLogger
import wslite.http.HTTPClientException
import wslite.soap.SOAPFaultException
import wslite.soap.SOAPResponse


/**
 * Extension to the wslite client for logging and error handling.
 * The package placement and class name is dictated by Groovy rules for Meta class loading (see http://groovy.codehaus.org/Using+the+Delegating+Meta+Class)
 * Method invocation on SOAPClient will be proxied by this class which adds convenience methods.
 *
 */
class SOAPClientMetaClass extends DelegatingMetaClass{

    //Delegating logger in our package name, so log4j configuration does not need to know about this weird package
    private final HttpLogger logger

    SOAPClientMetaClass(MetaClass delegate){
        super(delegate)
        logger = new HttpLogger()
    }

    @Override
    Object invokeMethod(Object object, String methodName, Object[] args) {
        if(methodName == "send"){
            withLogging {
                withExceptionHandler {
                    return super.invokeMethod(object, "send", args)
                }
            }
        } else {
            return super.invokeMethod(object, methodName, args)
        }
    }

    private SOAPResponse withLogging(Closure cl) {
        SOAPResponse response = cl.call()
        logger.log(response?.httpRequest, response?.httpResponse)
        return response
    }


    private SOAPResponse withExceptionHandler(Closure cl) {
        try {
            return cl.call()
        } catch (SOAPFaultException soapEx) {
            logger.log(soapEx.httpRequest, soapEx.httpResponse)
            def message = soapEx.hasFault() ? soapEx.fault.text() : soapEx.message
            throw new InfrastructureException(message)
        } catch (HTTPClientException httpEx) {
            logger.log(httpEx.request, httpEx.response)
            throw new InfrastructureException(httpEx.message)
        }
    }
}
于 2013-07-09T13:14:39.903 回答
0

只是提醒任何想重用此代码的人。

这实际上是一个坏主意，因为发送方法被soapclient本身重载和委托。结果是元类捕获了内部委托并记录了三到两次（取决于我调用的实际方法）。一次是我的调用，然后每次重载的方法调用其他方法。

我最终选择了一个类似于博客中描述的更简单的解决方案。那就是用我自己的包装实际的客户：

@Log4j
class WSClient {

    @Delegate
    final SOAPClient realClient

    WSClient(SOAPClient realClient) {
        this.realClient = realClient
    }

    SOAPResponse sendWithLog(args){
        withLogging{
            withExceptionHandler{
                realClient.send(args)
            }
        }
    }

    def withLogging = { cl ->
        SOAPResponse response = cl()
        logHttp(Level.DEBUG, response?.httpRequest, response?.httpResponse)
        return response
    }


    def withExceptionHandler = {cl ->
        try {
            return cl()
        } catch (SOAPFaultException soapEx) {
            logHttp(Level.ERROR, soapEx.httpRequest, soapEx.httpResponse)
            def message = soapEx.hasFault() ? soapEx.fault.text() : soapEx.message
            throw new InfrastructureException(message)
        } catch (HTTPClientException httpEx) {
            logHttp(Level.ERROR, httpEx.request, httpEx.response)
            throw new InfrastructureException(httpEx.message)
        }
    }

    private void logHttp(Level priority, HTTPRequest request, HTTPResponse response) {
        log.log(priority, "HTTPRequest $request with content:\n${request?.contentAsString}")
        log.log(priority, "HTTPResponse $response with content:\n${response?.contentAsString}")
    }
}
于 2013-07-15T11:22:25.637 回答