0

我制作了一个应该识别简单语法的程序。当我输入我认为应该是有效的陈述时，我得到一个错误。具体来说，如果我从一个标识符开始，我会自动得到一个语法错误。但是，我注意到如果标识符前面带有“int”，则使用标识符不会产生错误。如果 a 是一个标识符，那么如果我输入 'int a;' 还行吧。但是如果我输入 'a = 3' 我会得到一个错误。只需键入 a 本身就会产生错误。

lex 文件：

%{
#include <stdlib.h>
#include <ctype.h>
#include <string.h>

#include "y.tab.h"

%}

else else
if if
int int
return return
void void
while while
id [a-zA-Z]+
num [0-9]+
lte <=
gte >=
equal ==
notequal !=


%%

{else}  {   return ELSE; }
{if}    {   return IF; }
{int}   {   return INT; }
{return} {  return RETURN; }
{void} {    return VOID; }
{while} {   return WHILE; }
{id} {      return ID; }
{num} {     return NUM; }
{lte} {     return LTE; }
{gte} {     return GTE; }
{equal} {   return EQUAL; }
{notequal} {    return NOTEQUAL; }


[\[\];] { return yytext[0];}


%%

yacc 文件

/* C-Minus BNF Grammar */

%token ELSE
%token IF
%token INT
%token RETURN
%token VOID
%token WHILE

%token ID
%token NUM

%token LTE
%token GTE
%token EQUAL
%token NOTEQUAL
%%

program : declaration_list ;

declaration_list : declaration_list declaration | declaration ;

declaration : var_declaration | fun_declaration ;

var_declaration : type_specifier ID ';'
                | type_specifier ID '[' NUM ']' ';' ;

type_specifier : INT | VOID ;

fun_declaration : type_specifier ID '(' params ')' compound_stmt ;

params : param_list | VOID ;

param_list : param_list ',' param
           | param ;

param : type_specifier ID | type_specifier ID '[' ']' ;

compound_stmt : '{' local_declarations statement_list '}' ;

local_declarations : local_declarations var_declaration
                   | /* empty */ ;

statement_list : statement_list statement
               | /* empty */ ;

statement : expression_stmt
          | compound_stmt
          | selection_stmt
          | iteration_stmt
          | return_stmt ;

expression_stmt : expression ';'
                | ';' ;

selection_stmt : IF '(' expression ')' statement
               | IF '(' expression ')' statement ELSE statement ;

iteration_stmt : WHILE '(' expression ')' statement ;

return_stmt : RETURN ';' | RETURN expression ';' ;

expression : var '=' expression | simple_expression ;

var : ID | ID '[' expression ']' ;

simple_expression : additive_expression relop additive_expression
                  | additive_expression ;

relop : LTE | '<' | '>' | GTE | EQUAL | NOTEQUAL ;

additive_expression : additive_expression addop term | term ;

addop : '+' | '-' ;

term : term mulop factor | factor ;

mulop : '*' | '/' ;

factor : '(' expression ')' | var | call | NUM ;

call : ID '(' args ')' ;

args : arg_list | /* empty */ ;

arg_list : arg_list ',' expression | expression ;
4

2 回答 2

1

您是否在咀嚼空格？这是一个重要因素，因为您声明了 a[space]=[space]3。

于 2009-11-17T13:54:46.180 回答
1

程序扩展为declaration_list，declaration_list 只允许一系列声明。您实际上永远不会在语法中允许语句/表达式/等（函数定义内除外）。

于 2009-11-17T13:57:27.367 回答