3

我正在将这个半 html、半 xml wiki 翻译成 DITA。我的最终目标是根据 h 标题实现嵌套。基本上将节点后的节点（例如 h2）移动到节点之外body，并用topic/body. 标题级别可能会下降至h6.

我看到这篇解决了类似问题的帖子，但我没有足够的知识来修改它以在其他嵌套元素之前关闭 body 标签。

HTML/XML

<topic id="pageTitle">
   <title>Page Title</title>
   <body>
      <p>some contents.</p>
      <h2>heading title</h2>
      <p>some more content under h heading</p>

      <h3>sub-heading title</h3>
      <p>some more content under sub heading</p>
      <p>some more content under sub heading</p>

      <h2>heading title</h2>
      <p>some more content under h heading</p>
   </body>
</topic>

我想在DITA中实现嵌套

<topic id="pageTitle">
   <title>Page Title</title>
   <body>
      <p>some contents.</p>
   </body>

   <topic id="headingtitle">
      <title>heading title</title>
      <body>
         <p>some more content under h heading</p>
      </body>

      <topic id="sub-headingtitle">
         <title>sub-heading title</title>
         <body>
            <p>some more content under sub heading</p>
            <p>some more content under sub heading</p>
         </body>
      </topic>
   </topic>

   <topic id="headingtitle">
      <title>heading title</title>
      <body>
         <p>some more content under h heading</p>
      </body>
   </topic>
</topic>

请注意：<body>标签在其他主题开始之前关闭。这是 DITA 的标准，该主题不能嵌套在另一个主题的正文中。

此外，如果正文节点后面紧跟标题节点，则正文节点将被删除。

例如，XML

<topic id="pageTitle">
   <title>Page Title</title>
   <body>
      <h2>heading title</h2>
      <p>some more content under h heading</p>
   </body>
</topic>

目标

<topic id="pageTitle">
   <title>Page Title</title>

   <topic id="headingtitle">
      <title>h2 heading</title>
      <body>
         <p>some more content under h heading</p>
      </body>
   </topic>

</topic>
4

1 回答 1

4

这是我for-each-group group-starting-with在递归函数中使用 XSLT 2.0 的建议：

<xsl:stylesheet
  version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:mf="http://example.com/mf"
  exclude-result-prefixes="xs mf">

<xsl:output indent="yes"/>

<xsl:function name="mf:get-id-sub" as="xs:string">
  <xsl:param name="level" as="xs:integer"/>
  <xsl:sequence select="string-join(for $i in 3 to $level return 'sub-', '')"/>
</xsl:function>

<xsl:function name="mf:group" as="element()*">
  <xsl:param name="elements" as="element()*"/>
  <xsl:param name="level" as="xs:integer"/>
  <xsl:for-each-group select="$elements" group-starting-with="*[local-name() eq concat('h', $level)]">
    <xsl:choose>
      <xsl:when test="not(self::*[local-name() eq concat('h', $level)])">
        <body>
          <xsl:apply-templates select="current-group()"/>
        </body>
      </xsl:when> 
      <xsl:otherwise>
        <topic id="{mf:get-id-sub($level)}headingtitle">
          <xsl:apply-templates select="."/>
          <xsl:sequence select="mf:group(current-group() except ., $level + 1)"/>
        </topic>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:for-each-group>
</xsl:function>

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* , node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="topic[@id = 'pageTitle']/body">
  <xsl:sequence select="mf:group(*, 2)"/>
</xsl:template>

<xsl:template match="h2 | h3 | h4 | h5 | h6">
  <title>
    <xsl:apply-templates/>
  </title>
</xsl:template>

</xsl:stylesheet>

它转变

<topic id="pageTitle">
   <title>Page Title</title>
   <body>
      <h2>heading title</h2>
      <p>some more content under h heading</p>
   </body>
</topic>

进入

<topic id="pageTitle">
   <title>Page Title</title>
   <topic id="headingtitle">
      <title>heading title</title>
      <body>
         <p>some more content under h heading</p>
      </body>
   </topic>
</topic>

和

<topic id="pageTitle">
   <title>Page Title</title>
   <body>
      <p>some contents.</p>
      <h2>heading title</h2>
      <p>some more content under h heading</p>

      <h3>sub-heading title</h3>
      <p>some more content under sub heading</p>
      <p>some more content under sub heading</p>

      <h2>heading title</h2>
      <p>some more content under h heading</p>
   </body>
</topic>

进入

<topic id="pageTitle">
   <title>Page Title</title>
   <body>
      <p>some contents.</p>
   </body>
   <topic id="headingtitle">
      <title>heading title</title>
      <body>
         <p>some more content under h heading</p>
      </body>
      <topic id="sub-headingtitle">
         <title>sub-heading title</title>
         <body>
            <p>some more content under sub heading</p>
            <p>some more content under sub heading</p>
         </body>
      </topic>
   </topic>
   <topic id="headingtitle">
      <title>heading title</title>
      <body>
         <p>some more content under h heading</p>
      </body>
   </topic>
</topic>
于 2013-07-05T09:11:58.553 回答