2

在我的应用程序中，我有一个这样的类：

class sample{
    thrust::device_vector<int>   edge_ID;
    thrust::device_vector<float> weight;
    thrust::device_vector<int>   layer_ID;

/*functions, zip_iterators etc. */

};

在给定索引处，每个向量都存储同一条边的相应数据。

我想编写一个函数来过滤给定层的所有边缘，如下所示：

void filter(const sample& src, sample& dest, const int& target_layer){
      for(...){
        if( src.layer_ID[x] == target_layer)/*copy values to dest*/;
      }
}

我发现做到这一点的最好方法是使用thrust::copy_if(...) （详细信息）

它看起来像这样：

void filter(const sample& src, sample& dest, const int& target_layer){
     thrust::copy_if(src.begin(),
                     src.end(),
                     dest.begin(),
                     comparing_functor() );
}

这就是我们遇到问题的地方：

这comparing_functor()是一个一元函数，这意味着我不能将我的target_layer值传递给它。

任何人都知道如何解决这个问题，或者有一个想法来实现这一点，同时保持类的数据结构完整？

4

1 回答 1

3

除了通常传递给它们的数据之外，您还可以将特定值传递给函子以在谓词测试中使用。这是一个工作示例：

#include <iostream>
#include <thrust/host_vector.h>
#include <thrust/device_vector.h>
#include <thrust/sequence.h>
#include <thrust/copy.h>

#define DSIZE 10
#define FVAL 5

struct test_functor
{
  const int a;

  test_functor(int _a) : a(_a) {}

  __device__
  bool operator()(const int& x ) {
    return (x==a);
    }
};

int main(){
  int target_layer = FVAL;
  thrust::host_vector<int> h_vals(DSIZE);
  thrust::sequence(h_vals.begin(), h_vals.end());
  thrust::device_vector<int> d_vals = h_vals;
  thrust::device_vector<int> d_result(DSIZE);
  thrust::copy_if(d_vals.begin(), d_vals.end(), d_result.begin(),  test_functor(target_layer));
  thrust::host_vector<int> h_result = d_result;
  std::cout << "Data :" << std::endl;
  thrust::copy(h_vals.begin(), h_vals.end(), std::ostream_iterator<int>( std::cout, " "));
  std::cout << std::endl;
  std::cout << "Filter Value: " << target_layer << std::endl;
  std::cout << "Results :" << std::endl;
  thrust::copy(h_result.begin(), h_result.end(), std::ostream_iterator<int>( std::cout, " "));
  std::cout << std::endl;
  return 0;
}
于 2013-07-04T13:03:34.080 回答