android - Android Studio：如何创建用于 Jenkins 的 build.gradle 文件？

Question

我是 gradle 新手，并试图弄清楚如何在我们的 Jenkins 构建机器上进行设置。我们的应用程序在 Android Studio 中完美构建，但它不会生成 build.gradle 文件，我相信我需要该文件才能在 Jenkins 上运行 gradle 构建。

任何帮助表示赞赏！

Answer 1

我最终从头开始创建这些构建文件。

以下是一些指导方针：

1. 如果您有一个包含多个模块的项目，请在项目的根目录（与所有模块处于同一级别）创建一个 settings.gradle 文件。您的 settings.gradle 文件应如下所示：

   include 'ActionBarSherlock'
   include ':facebook-android-sdk-3.0.1:facebook'
   include 'google-play-services_lib'
   include ':SlidingMenu-master:library'
   include 'Tinder'
   include 'ViewPagerIndicator'
   include 'volley'
   include 'windowed-seek-bar'
   

2. 在每个模块中，创建一个 build.gradle 文件。对于库项目，您的 build.gradle 文件应如下所示：

   buildscript {
       repositories {
           mavenCentral()
       }
   
       dependencies {
           classpath 'com.android.tools.build:gradle:0.4.2'
       }
   }
   
   apply plugin: 'android-library'
   
   dependencies {
       compile 'com.android.support:support-v4:13.0.0'
   }
   
   android {
       buildToolsVersion "17.0"
       compileSdkVersion 17
   
       sourceSets {
           main {
               manifest.srcFile 'AndroidManifest.xml'
               java.srcDirs = ['src']
               resources.srcDirs = ['src']
               aidl.srcDirs = ['src']
               renderscript.srcDirs = ['src']
               res.srcDirs = ['res']
               assets.srcDirs = ['assets']
           }
   
           instrumentTest.setRoot('tests')
       }
   }
   

3. 对于您的主项目，您的 build.gradle 文件应如下所示：

   buildscript {
       repositories {
           mavenCentral()
       }
   
       dependencies {
           classpath 'com.android.tools.build:gradle:0.4.2'
       }
   }
   
   apply plugin: 'android'
   
   dependencies {
       compile project(':facebook-android-sdk-3.0.1:facebook')
       compile project(':google-play-services_lib')
       compile project(':SlidingMenu-master:library')
       compile project(':ViewPagerIndicator')
       compile project(':volley')
       compile project(':windowed-seek-bar')
       compile files('compile-libs/androidannotations-2.7.1.jar', 'libs/Flurry_3.2.1.jar', 'libs/google-play-services.jar', 'libs/gson-2.2.4.jar', 'libs/picasso-1.1.1.jar')
   }
   
   android {
       buildToolsVersion "17.0"
       compileSdkVersion 17
   
       sourceSets {
           main {
               manifest.srcFile 'AndroidManifest.xml'
               java.srcDirs = ['src']
               resources.srcDirs = ['src']
               aidl.srcDirs = ['src']
               renderscript.srcDirs = ['src']
               res.srcDirs = ['res']
               assets.srcDirs = ['assets']
           }
       }
   }