21

我收到此错误：

（此时出乎意料

接受 的值后发生错误a。我尝试并检查了可能导致此类问题的空值，但没有成功。

echo off
cls
title ~USB Wizard~
echo What do you want to do?
echo 1.Enable/Disable USB Storage Devices.
echo 2.Enable/Disable Writing Data onto USB Storage.
echo 3.~Yet to come~.

set "a=%globalparam1%"
goto :aCheck
:aPrompt
set /p "a=Enter Choice: "
:aCheck
if "%a%"=="" goto :aPrompt
echo %a%

IF %a%==2 (
title USB WRITE LOCK
echo What do you want to do?
echo 1.Apply USB Write Protection
echo 2.Remove USB Write Protection
::param1
set "param1=%globalparam2%"
goto :param1Check
:param1Prompt
set /p "param1=Enter Choice: "
:param1Check
if "%param1%"=="" goto :param1Prompt

if %param1%==1 (
REG ADD HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\StorageDevicePolicies\ /v WriteProtect /t REG_DWORD /d 00000001 
echo USB Write is Locked!
)
if %param1%==2 (
REG ADD HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\StorageDevicePolicies\ /v WriteProtect /t REG_DWORD /d 00000000
echo USB Write is Unlocked! 
)
)
pause
4

4 回答 4

30

您收到该错误是因为在param1评估 if 语句时，由于是范围变量而没有延迟扩展，因此 param 始终为 null。

使用括号时，括号内的所有命令和变量都会展开。那时， param1 没有使 if 语句无效的价值。使用延迟扩展时，仅在实际调用命令时才扩展变量。

我还建议使用if not defined命令来确定是否设置了变量。

@echo off
setlocal EnableExtensions EnableDelayedExpansion
cls
title ~USB Wizard~
echo What do you want to do?
echo 1.Enable/Disable USB Storage Devices.
echo 2.Enable/Disable Writing Data onto USB Storage.
echo 3.~Yet to come~.

set "a=%globalparam1%"
goto :aCheck
:aPrompt
set /p "a=Enter Choice: "
:aCheck
if not defined a goto :aPrompt
echo %a%

IF "%a%"=="2" (
    title USB WRITE LOCK
    echo What do you want to do?
    echo 1.Apply USB Write Protection
    echo 2.Remove USB Write Protection

    ::param1
    set "param1=%globalparam2%"
    goto :param1Check
    :param1Prompt
    set /p "param1=Enter Choice: "
    :param1Check
    if not defined param1 goto :param1Prompt
    echo !param1!

    if "!param1!"=="1" (
        REG ADD HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\StorageDevicePolicies\ /v WriteProtect /t REG_DWORD /d 00000001 
        echo USB Write is Locked!
    )
    if "!param1!"=="2" (
        REG ADD HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\StorageDevicePolicies\ /v WriteProtect /t REG_DWORD /d 00000000
        echo USB Write is Unlocked! 
    )
)
pause
endlocal
于 2013-07-01T21:33:12.657 回答
13

哦亲爱的。几个小问题...

正如其他人指出的那样，您需要引用以防止出现空/包含空格的条目，并使用 !delayed_expansion! 设施。

您应该注意的另外两个事项：

首先，set/p将用户输入的值分配给变量。这不是新闻 - 但问题是按下enter响应将使变量保持不变 - 它不会为变量分配零长度字符串（因此从环境中删除变量。）安全方法是：

 set "var="
 set /p var=

也就是说，当然，如果您不想enter重复现有值。
另一种有用的形式是

 set "var=default"
 set /p var=

或者

 set "var=default"
 set /p "var=[%var%]"

（使用默认值提示；!var!如果在延迟扩展的块语句中）

第二个问题是，在某些 Windows 版本上（尽管 W7 似乎“修复”了这个问题）任何标签 - 包括 a :: comment（这是一个损坏的标签）都将终止任何“块” - 即带括号的复合语句）

于 2013-07-02T01:05:32.513 回答
11

您在所有三个if语句中都需要双引号，例如：

IF "%a%"=="2" (

@echo OFF &SETLOCAL ENABLEDELAYEDEXPANSION
cls
title ~USB Wizard~
echo What do you want to do?
echo 1.Enable/Disable USB Storage Devices.
echo 2.Enable/Disable Writing Data onto USB Storage.
echo 3.~Yet to come~.


set "a=%globalparam1%"
goto :aCheck
:aPrompt
set /p "a=Enter Choice: "
:aCheck
if "%a%"=="" goto :aPrompt
echo %a%

IF "%a%"=="2" (
    title USB WRITE LOCK
    echo What do you want to do?
    echo 1.Apply USB Write Protection
    echo 2.Remove USB Write Protection
    ::param1
    set "param1=%globalparam2%"
    goto :param1Check
    :param1Prompt
    set /p "param1=Enter Choice: "
    :param1Check
    if "!param1!"=="" goto :param1Prompt

    if "!param1!"=="1" (
         REG ADD HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\StorageDevicePolicies\ /v WriteProtect /t REG_DWORD /d 00000001
         USB Write is Locked!
    )
    if "!param1!"=="2" (
         REG ADD HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\StorageDevicePolicies\ /v WriteProtect /t REG_DWORD /d 00000000
         USB Write is Unlocked!
    )
)
pause
于 2013-07-01T20:19:35.927 回答
0

如果您在 IF 语句中遇到此错误，请检查是否使用了您的 double 等于来比较您的变量。

例如。

IF [%checkresult%]=1 GOTO INVALID

这会抛出“此时 =1 是意外的。”

要更正此问题，请添加另一个等号。

IF [%checkresult%]==1 GOTO INVALID
于 2021-06-12T13:08:47.500 回答