file - vbscript 在所有文件中查找具有特定文件名的最近文件

Question

我只有以下文件。

New Text Document - Copy (1)

New Text Document - Copy (2)

New Text Document - Copy (3)

New Text Document - Copy (4)

New Text Document - Copy (5)

除此之外，我还有类似的东西

Test1.pdf

test2.pdf

Test3.pdf

我的要求是找到文件名为“新文本文档”的最新文件

Answer 1

为了让你开始：

  ' need a FSO for folder access
  Dim oFS    : Set oFS    = CreateObject("Scripting.FileSystemObject")
  ' hold the file found (if any)
  Dim oFiFnd : Set oFiFnd = Nothing
  ' smallest possible number
  Dim nMax   : nMax       = 0
  ' define which files to consider
  Dim reFiNa : Set reFiNa = New RegExp
  reFiNa.Pattern = "^New Text Document - Copy \((\d+)\)$"
  Dim oFile, oMTS
  ' look at all files in folder
  For Each oFile In oFS.GetFolder("..\testdata\17405017").Files
      Set oMTS = reFiNa.Execute(oFile.Name)
      If 1 = oMTS.Count Then
         ' file confirms to pattern
         If nMax < CLng(oMTS(0).SubMatches(0)) Then
            ' largest nMax seen so far
            nMax       = CLng(oMTS(0).SubMatches(0))
            Set oFiFnd = oFile
         End If
      End If
  Next
  If oFiFnd Is Nothing Then
     ' search failed
     WScript.Echo "No file found."
  Else
     ' success
     WScript.Echo "found", oFiFnd.Path
  End If

更新 wrt 评论：

如果 RegExp 没有找到任何文件，则文件夹中没有像“新建文本文档 - 副本 (1)”这样的文件。您可以尝试@Ansgar 不那么严格的过滤器 - 只需查看文件名的前 17 个字符 - 或修改 .Pattern - 例如 ""^New Text Document - Copy ((\d+)).doc$" 如果您忘记了.doc 扩展名。

查看@Ansgar 的贡献也可以帮助您澄清您的规格：“最新”是指“最后修改的文件”还是“最高副本 (#)”？

Answer 2

枚举文件夹中的文件，如下所示：

Set fso = CreateObject("Scripting.FileSystemObject")
For Each f In fso.GetFolder("C:\some\where").Files
  WScript.Echo f.Name
Next

像这样检查文件的名称（用于LCase()使检查不区分大小写）：

If LCase(Left(f.Name, 17)) = "new text document" Then
  'do stuff
End If

记住最近修改的文件，如下所示：

Set mostRecent = Nothing
...
If mostRecent Is Nothing Then
  Set mostRecent = f
ElseIf f.DateLastModified > mostRecent.DateLastModified Then
  Set mostRecent = f
End If