0

我正在尝试解析：

<?xml version="1.0" encoding="utf-8"?><soap:Envelope xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema"><soap:Body><LoginResponse xmlns="http://services.marketernet.com/application"><LoginResult><results><response value="UY+/9dD+Lz7DT3Oq/WG3CVJ/pFW7o6LEFNA4xOSIWr88Dh2RVAgy9qHP1BwpdiYA"/><exceptions></exceptions></results></LoginResult></LoginResponse></soap:Body></soap:Envelope>

到目前为止，我有：

<cfset soapResponse = xmlParse(httpResponse.fileContent) />
<cfset results = xmlSearch(soapResponse,"//*[local-name()='LoginResult' and namespace-uri()='http://services.marketernet.com/application']") />

我需要的价值<response value="UY+/9dD+Lz7DT3Oq/WG3CVJ/pFW7o6LEFNA4xOSIWr88Dh2RVAgy9qHP1BwpdiYA"/>

我尝试循环，甚至尝试做一个深层的 xml 路径，什么都没有。

请帮助我，如果您有任何问题，请告诉我。

更新 1：“屏幕截图” 截屏

更新2：“截图长版” 截屏

4

1 回答 1

1

我通常只是使用xmlSearch(soapResponse,"//*[local-name()='whatever']")它，它对我来说很好用。根据您在 XML 中搜索的深度，它可以返回不同的类型。因此，在开发代码时，我总是<cfdump>用来查看xmlSearch()函数的结果以了解我在处理什么。

我采用了您共享的 SOAP 响应，并在 ColdFusion 9.0.1 上成功测试了以下代码。请注意，我在这里进行了三个不同的搜索，每个搜索都深入研究了 XML 树。我把它<cfdump>留在那里，这样你就可以看到每个返回的内容。

<cftry>
<cfsavecontent variable="content">
    <?xml version="1.0" encoding="UTF-8" ?>
    <soap:Envelope xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
        <soap:Body>
            <LoginResponse xmlns="http://services.marketernet.com/application">
                <LoginResult>
                    <results>
                        <response value="UY+/9dD+Lz7DT3Oq/WG3CVJ/pFW7o6LEFNA4xOSIWr88Dh2RVAgy9qHP1BwpdiYA"/>
                        <exceptions></exceptions>
                    </results>
                </LoginResult>
            </LoginResponse>
        </soap:Body>
    </soap:Envelope>
</cfsavecontent>
<cfset soapResponse = xmlParse(Trim(content)) />

<html>
    <head><title>Test xmlParse</title></head>
    <body>
        <h3>xmlParse option 1</h3>
        <div>
            <cfset results = xmlSearch(soapResponse,"//*[local-name()='LoginResult']") />
            <cfdump var="#results#" />
            <cfset value = results[1].results.response.XmlAttributes.value />
            <cfdump var="#value#" />
        </div>
        <h3>xmlParse option 2</h3>
        <div>
            <cfset results = xmlSearch(soapResponse,"//*[local-name()='results']") />
            <cfdump var="#results#" />
            <cfset value = results[1].response.XmlAttributes.value />
            <cfdump var="#value#" />
        </div>
        <h3>xmlParse option 3</h3>
        <div>
            <cfset results = xmlSearch(soapResponse,"//*[local-name()='response']") />
            <cfdump var="#results#" />
            <cfset value = results[1].XmlAttributes.value />
            <cfdump var="#value#" />
        </div>
    </body>
</html>
<cfcatch type="any">
    <cfdump var="#cfcatch#" />
</cfcatch>
</cftry>

所有选项都会将value变量设置为UY+/9dD+Lz7DT3Oq/WG3CVJ/pFW7o6LEFNA4xOSIWr88Dh2RVAgy9qHP1BwpdiYA来自 XML。

于 2013-07-02T18:37:05.293 回答