0

我想用来AnyEvent::DNS在某些 DNS 服务器上解析我的域。服务器列表来自两个地方，每个地方大约有 60 多个服务器。当我只为一个服务器列表运行解析时，没问题。但是如果我为所有列表运行解析，我得到一个错误："unable to create either an IPv4 or an IPv6 socket".

我的脚本如下：

#!/usr/bin/perl
use Modern::Perl;
use AnyEvent::DNS;
use AnyEvent::Socket;
use AnyEvent;
use Module::Runtime qw/require_module/;
use lib './lib';

my $domain = $ARGV[0] // 'fmn.xnimg.cn';
my $cv = AnyEvent->condvar;

for my $mod ( ( 'DNS::xixik', 'DNS::yqie' ) ) {  # error
#for my $mod ( ( 'DNS::xixik' ) ) {  # ok
    require_module($mod);
    my $dnslist = $mod->new->get_dnslist;
    for my $isp ( keys %$dnslist ) {
        while ( my ( $addr, $dns ) = each %{ $dnslist->{$isp} } ) {
            resolv( $isp . $addr, $_, $domain ) for @{$dns};
        }
    }
}
$cv->recv;

sub resolv {
    my ( $addr, $dns, $domain ) = @_;
    my $resolver = AnyEvent::DNS->new(
        server => [ AnyEvent::Socket::parse_address $dns ],
    );
    $cv->begin;
    $resolver->resolve(
        "$domain" => 'a',
        sub {
            my @ips = map { $_->[-1] } @_;
            printf "%s (%s) => %s\n", $dns, $addr, join( ", ", @ips ) if @ips;
            $cv->end;
        }
    );
}
4

1 回答 1

1

AnyEvent::DNS 没有人为限制，但是并行未完成查询的数量限制在 max_outstanding 配置值（超过这个限制只会延迟请求，不会导致错误）。但是，您为每个请求创建一个解析器 - 每个解析器都需要一个或多个套接字，这可能是您看到的问题（通常您应该能够创建 500 多个解析器，除非您的程序中的其他代码也创建了很多句柄，或者您正在使用 Windows）。

如果你真的需要这么多解析器，你需要增加文件描述符限制 - 在 unix 上，你可以在启动脚本之前使用 ulimit -n 来做到这一点。

于 2013-12-29T00:16:17.910 回答