1

在第一次使用命令行和 ImageMagic 摆弄之后，我已经能够做到以下几点：

c:\test\paper.pdf contains a pdf file
c:\test>convert paper.pdf output-%d.tiff

该pdf文件包含五个页面，并且输出是预期的 5 个 tiff 文件 :-) 现在我想放入多个文件c:\test并循环它们，根据原始文件名创建页面。因此，假设以下文件位于c:\test：

paper.pdf     (5 pages)
example.pdf   (2 pages)
new.pdf       (1 page)

批处理脚本的输出应该是文件c:\test\tiffs\夹中的 8 个 tiff 文件：

paper-0.tiff paper-1.tiff paper-2.tiff paper-3.tiff paper-4.tiff
example-0.tiff example-1.tiff
new-0.tiff

我非常希望命令行返回将 pdf 转换为 tiff 所花费的时间：

c:\test>convert.bat
c:\test>This action took 120 seconds

我正在尝试编写此批处理文件，但由于这是我的第一次尝试，我遇到了麻烦。我首先尝试遍历该test文件夹并创建所有 tiff（暂时保留该过程的时间）：

for %%f in (C:\test\) do convert %%f.pdf %%f-%%d.tiff

我原以为这会起作用，但出现错误：

C:\Users\Me>convert c:\test\c:\test\.pdf c:\test\c:\test\-%d.tiff convert.exe: 
unable to open image `c:\test\c:\test\.pdf': Invalid argument @ 
error/blob.c/OpenBlob/2646. convert.exe: no decode delegate for this image 
format `c:\test\c:\test\.pdf' @ error/constitute.c/ReadImage/552. convert.exe: 
no images defined `c:\test\c:\test\-%d.tiff' @ 
error/convert.c/ConvertImageCommand/3106.

我究竟做错了什么？

4

1 回答 1

2

定时

这是使用批处理/CMD做错的工作之一（实际上——做它来炫耀是可以的）。我遇到的几乎每一种编程语言都比 CMD 做得更好。

如果经过的时间超过任何给定日期的午夜，则此特定（hackish）实现将不起作用，并且取决于您在区域设置中配置日期的方式，如果运行在下午 1 点之前开始并在下午 1 点之后结束，它可能会中断

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION

FOR /F "tokens=5 delims= " %%t IN ('^<NUL time') DO SET START_TIME=%%t

:: Stuff that you're timing.

FOR /F "tokens=5 delims= " %%t IN ('^<NUL time') DO SET END_TIME=%%t

SET ELAPSED=
FOR /F "delims=:. tokens=1,2,3,4" %%a IN ("%START_TIME%") DO (
    FOR /F "delims=:. tokens=1,2,3,4" %%n IN ("%END_TIME%") DO (
        SET /A HOURS=%%n-%%a
        SET /A MINUTES=%%o-%%b
        SET /A SECONDS=%%p-%%c
        SET /A HUND=%%q-%%d

        SET /A TOTAL=!HOURS!*3600 + !MINUTES!*60 + !SECONDS!
        IF !HUND! LSS 0 (
            SET /A TOTAL=!TOTAL!-1
            SET /A HUND=!HUND!+100
        )
        IF !HUND! LSS 10 SET HUND=0!HUND!

        SET ELAPSED=!TOTAL!.!HUND!
    )
)

@ECHO.
@ECHO.
@ECHO This action took %ELAPSED% seconds.

ImageMagick

我在您的convert命令中看到的问题是您没有告诉 CMD 要搜索什么模式。这听起来像你想要*.pdf的。这样做意味着您不需要将“.pdf”附加到输入文件名的末尾，并且在指定输出文件名时需要删除扩展名。%%~dpnf生成不带扩展名的文件的完整路径。

FOR %%f IN (C:\temp\*.pdf) do convert "%%~f" "%%~dpnf-%%d.tiff"

编辑：要将 PDF 放在不同的位置，请更改%%f替换：

FOR %%f IN (C:\temp\*.pdf) do convert "%%~f" "\path\to\tiffs\%%~nf-%%d.tiff"

更好的方法？

我想我至少应该插上一个插头来做正确的™方式。如果您不想从支持计时的语言（如 Python）的脚本中调用命令，则可以将系统时间检索为整数。这个策略将一直有效到大约 2038 年。我在这个例子中使用了 Perl。

@ECHO OFF

FOR /F %%t IN ('perl -e "print(time());"') DO SET START_TIME=%%t

:: stuff to time

FOR /F %%t IN ('perl -e "print(time());"') DO SET END_TIME=%%t
SET /A ELAPSED=%END_TIME%-%START_TIME%
@ECHO This step took %ELAPSED% seconds.
于 2013-06-27T16:34:43.473 回答