0

我想为阿拉斯加 (AK) 和夏威夷 (HI) 添加 25 美元的固定手续费 - 当我将州和固定费用添加到下面的运输矩阵时，我的测试中断了。有人可以指出我正确的方向吗？

my $totalPounds = sprintf("%.2f",($totalWeight / 16));
#my $shipping = &getShipUPS($totalPounds, $zip, $shipType);
if ($subtotal <= 24.99) {$shipping = '10.95';}
elsif (($subtotal > 24.99) && ($subtotal <= 74.99)) {$shipping = '13.95';}
elsif (($subtotal > 74.99) && ($subtotal <= 149.99)) {$shipping = '14.95';}
elsif ($subtotal >= $150) {$shipping = '18.95';}
elsif ($state eq 'HI','AK') ($subtotal <= 24.99) {$shipping = '10.95'+'25.00';}
elsif ($state eq 'HI','AK') (($subtotal > 24.99) && ($subtotal <= 74.99)) {$shipping = '13.95'+'25.00';}
elsif ($state eq 'HI','AK') (($subtotal > 74.99) && ($subtotal <= 149.99)) {$shipping = '14.95'+'25.00';}
elsif ($state eq 'HI','AK') ($subtotal >= $150) {$shipping = '18.95'+'25.00';}else 

$shipping = sprintf("%.2f", $shipping);

my $total = $subtotal + $tax + $shipping;
$subtotal = sprintf("%.2f", $subtotal);
$total = sprintf("%.2f", $total);
4

2 回答 2

2

你不能eq像这样使用多个参数

$state eq 'HI','AK'

你需要做

$state eq 'HI' or $state eq 'AK'

另外，你不能elsif像这样在第一个之后加上另一个括号

elsif ($state eq 'HI','AK') ($subtotal >= $150)

你需要做

elsif ( ($state eq 'HI' or $state eq 'AK') or ($subtotal >= $150) )
#     ^----               main parantheses                 -------^

当然，更明智的选择可能是使用哈希

%extra_charges = ( AK => 25, 
                   HI => 25,
                   # etc
);
...
$subtotal += $extra_charges{$state};   # assuming no missing states

if-else 逻辑也是各种多余的。这应该等同于您的代码：

if    ($subtotal <= 24.99)            { $shipping = '10.95' }
elsif ($subtotal <= 74.99)            { $shipping = '13.95' }
elsif ($subtotal <= 149.99)           { $shipping = '14.95' }
else                                  { $shipping = '18.95' }

if ($state eq 'AK' or $state eq 'HI') { $shipping += 25 }

那些曲折的ifs森林，足以让人头晕目眩，而且大部分都不需要。如果一个值不小于或等于 24.99，它必须大于 24.99，所以不需要仔细检查。

于 2013-06-26T10:14:50.350 回答
1

该代码一团糟，有多个语法错误，并且违反了 DRY。

最好先根据小计计算基本运费。如果州是夏威夷或阿拉斯加，则在第二步中添加 25 美元的费用：

my @shipping_fees = (
  # max subtotal => fee
  [  24.99 => 10.95 ],
  [  74.99 => 13.95 ],
  [ 149.99 => 14.95 ],
  [ inf    => 18.95 ],
);

my %extra_fees_per_state = (
  AK => 25.00,
  HI => 25.00,
);

然后：

my $shipping;
for my $shipping_fee (@shipping_fees) {
  my ($max, $fee) = @$shipping_fee;
  if ($subtotal <= $max) {
    $shipping = $fee;
    last;
  }
}

if (defined( my $extra = $extra_fees_per_state{$state})) {
  $shipping += $extra;
}
于 2013-06-26T10:25:50.557 回答