3

我想使用 SPARQL 创建观察排名。假设我有：

@prefix : <http://example.org#> .

:A :value 60 .
:B :value 23 .
:C :value 89 .
:D :value 34 .

排名应该是：：C = 1（最高），：A = 2，：D = 3，：B = 4。到目前为止，我可以使用以下查询来解决它：

prefix : <http://example.org#> 
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

SELECT ?x ?v ?ranking { 
 ?x :value ?v .
 { SELECT (GROUP_CONCAT(?x;separator="") as ?ordered) {
    { SELECT ?x {
       ?x :value ?v .
      } ORDER BY DESC(?v)
    }
   }
 }
 BIND (str(?x) as ?xName)
 BIND (strbefore(?ordered,?xName) as ?before) 
 BIND ((strlen(?before) / strlen(?xName)) + 1 as ?ranking)
} ORDER BY ?ranking

但该查询仅在 URI?x的长度相同时才有效。更好的解决方案是使用类似于strposPHP 或isIndexOfJava 的函数，但据我所知，它们在 SPARQL 1.1 中不可用。有更简单的解决方案吗？

4

1 回答 1

6

这样做的一种方法是将小于或等于它的值的数量作为值的排名。这对于较大的数据集可能效率低下，因为对于每个值，它必须检查所有其他值。虽然它不需要字符串操作。

PREFIX : <http://example.org#>

SELECT ?x ?v (COUNT(*) as ?ranking) WHERE {
  ?x :value ?v .
  [] :value ?u .
  FILTER( ?v <= ?u )
}
GROUP BY ?x ?v
ORDER BY ?ranking


---------------------
| x  | v  | ranking |
=====================
| :C | 89 | 1       |
| :A | 60 | 2       |
| :D | 34 | 3       |
| :B | 23 | 4       |
---------------------
于 2013-06-26T13:06:01.083 回答