2

我想创建抛出应用程序错误的程序。此程序应放在单独的包中。

procedue Raise_Error(error_code) is
err t_Error;
begin
      err:= error_list(error_code);
      raise_application_error(err.error_number, err.message);
end;

所以我在包内创建了类型：

type t_Error is record (error_number INTEGER, message VARCHAR2(200));
type t_Error_List is table of t_Error index by VARCHAR(30);
error_list t_Error_List ;

我怎样才能创建这样的错误常量列表：

const1 t_Error := t_Error (-200001, 'first message');
const2 t_Error := t_Error (-200002, 'second message');

error_list ('code1') := const1;
error_list ('code2') := const2;

非常感谢。鲍勃

4

1 回答 1

1

您可以在包的begin/end块中创建错误表（将为调用包的每个会话创建错误表），但您不能实例化这样的记录；您需要独立设置字段值：

create package body error_pkg as
  procedure Raise_Error(error_code in varchar2) is
    err t_Error;
  begin
    err := error_list(error_code);
    raise_application_error(err.error_number, err.message);
  end Raise_Error;

begin
  error_list ('code1').error_number := -20001;
  error_list ('code1').message := 'first message';
  error_list ('code2').error_number := -20002;
  error_list ('code2').message := 'second message';
end error_pkg;
/

使用虚拟 PL/SQL 块调用过程：

begin
  error_pkg.raise_error('code2');
end;
/

Error report:
ORA-20002: second message
ORA-06512: at "STACKOVERFLOW.ERROR_PKG", line 6
ORA-06512: at line 2

SQL 小提琴演示。

我不确定这是一个好主意。您正在丢失原始问题的堆栈跟踪 - 您不知道raise_error调用是从哪里发出的。也许这对您自己的错误无关紧要；但如果你捕捉到一个真正的异常并改为调用它，那将是一个坏主意。

于 2013-06-25T10:38:07.757 回答