5

我已经尝试过搜索，但似乎无法在任何地方找到答案，所以希望这里有人可以提供帮助。我想根据计数是否大于一来插入条件 XML 标记，但不知道该怎么做。

例如，我有两个这样的 XElement：

<Blob>
<Group>
Stuff 1
</Group>
</Blob>

和

<Blob>
<Group>
Stuff 1
</Group>
<Group>
Stuff 2
</Group>
</Blob>

我希望这最终成为第一个：

<BigGroup>
<Group/>
</BigGroup>

对于第二个：

<BigGroup>
<Groups>
<Group/>
<Group/>
</Groups>
</BigGroup>

注意在第二个中，它们是围绕两组的标签。

所以，我想要 XML Literal 中的那个条件。我试过的是：

Dim groups = If(<Blob>.<Group>.Count > 1, <Groups/>, Nothing)

Dim bigGroup = <BigGroup><%= groups %><%= from e in <Blob>.<Group> select e %><%= groups%></BigGroup>

但这行不通。有没有人可以按照上面的要求从 XML Literal 中执行此操作？

4

1 回答 1

13

您可以将 If 语句放在 XML 文本中。IEnumerable(Of XElement)此外，通过简单地引用里面的变量来输出一个是足够聪明的<%= %>。

这是代码。

Sub Main()
    Dim SingleGroup = <Blob>
                          <Group>Stuff 1</Group>
                      </Blob>

    Dim TwoGroups = <Blob>
                        <Group>Stuff 1</Group>
                        <Group>Stuff 2</Group>
                    </Blob>

    Dim BigGroup1 = BigGroup(SingleGroup.<Group>)

    Dim BigGroup2 = BigGroup(TwoGroups.<Group>)

    Console.WriteLine(BigGroup1)
    Console.WriteLine()

    Console.WriteLine(BigGroup2)
    Console.ReadLine()

End Sub

Function BigGroup(ByVal groups As IEnumerable(Of XElement)) As XElement
    Dim result = <BigGroup>
                     <%= If(groups.Count > 1, _
                         <Groups><%= groups %></Groups>, _
                         groups.SingleOrDefault) %>
                 </BigGroup>
    Return result
End Function

输出是：

<BigGroup>
  <Group>Stuff 1</Group>
<BigGroup>

<BigGroup>
  <Groups>
    <Group>Stuff 1</Group>
    <Group>Stuff 2</Group>
  </Groups>
</BigGroup>
于 2009-11-14T07:52:31.777 回答