1

我正在尝试编写一个批处理文件来监视日志文件中是否存在“rdy”一词，并在针对 rdy 的值小于 200 时发出警报

从我的日志文件中提取如下：

[Sun Jun 23 11:00:00 2013] [notice] mpmstats: rdy 249 bsy 1 rd 0 wr 1 ka 0 log 0 dns 0 cls 0
[Sun Jun 23 11:00:02 2013] [error] [client 10.25.134.1] File does not exist: E:/htdocs/default/KeepAlive.html

我编写了一个基本脚本（仍然在我的 L 上），它监视特定目录中的 error.log 文件。问题是有几天的错误日志，我想监控当前的错误日志。

@echo off

set log=E:\scripts\busycheckalert.log
set Time=%time:~0,5%
set Today=%date:~4,2%
set Month=%date:~7,2%
set Year=%date:~12,2%
set file=E:\logs\ihs\Default\error.log.%Month%.%Today%.%Year%

echo Polling %file% at %Time% >> %log%
for /f "usebackq delims=;" %%a in (`dir /b   E:\logs\ihs\Default\error.log.%Month%.%Today%.%Year%`) do (
    echo Checking now >> %log%
    for /f "tokens=8,9 delims= " %%a in     (E:\logs\ihs\Default\error.log.%Month%.%Today%.%Year%) do (
        echo Doing Checks >> %log%
        if %%j LEQ 200 echo %Today%-%Month%-%Year% at %Time% Error - Ready threshold exceeded >> %log% in %%a ))

我设法到达第一个检查点“现在检查”。但是，它似乎没有进入第二个循环。

这是生成的日志文件的摘录：

Polling E:\logs\ihs\Default\error.log.06.23.13 at 22:48 
Checking now 
Polling E:\logs\ihs\Default\error.log.06.23.13 at 22:49 
Checking now 
Polling E:\logs\ihs\Default\error.log.06.23.13 at 22:50 
Checking now

你能告诉我哪里出错了吗？任何帮助都会很棒。

谢谢

4

4 回答 4

2 
for /f "tokens=8,9 delims= " %%a in     (E:\logs\ihs\Default error.log.%Month%.%Today%.%Year%) do (

嗯-现在我想知道如果您将其更改%%a为，例如，会发生什么%%i？

您似乎也没有检查%%i==rdy 。如果你不这样做，你可能会得到一些相当奇怪的结果。

于 2013-06-23T13:26:49.777 回答
2

GNUWin32 代码建议：

@echo off & setlocal
set "cTime=%time:~0,5%"
set "Today=%date:~3,2%"
set "Month=%date:~6,2%"
set "Year=%date:~11,2%"
set "file=E:\logs\ihs\Default\error.log.%Month%.%Today%.%Year%"
SET "log=resultant.log"

echo Polling %file% at %Time% >> "%log%"
for /f "delims=" %%a in ('dir /b /a-d "%file%') do (
     echo Checking now >> "%log%"
     for /f "tokens=3" %%b IN ('grep -o "mpmstats: rdy [0-9]\+" "%file%"') do SET "rdy=%%b"
     echo Doing Checks >> "%log%"
     SETLOCAL ENABLEDELAYEDEXPANSION
     if !rdy! LEQ 200 echo %Today%-%Month%-%Year% at %cTime% Error - Ready threshold exceeded IN %%a >> "%log%"
     endlocal
)
于 2013-06-23T14:09:52.943 回答
2

The issue is there are error logs from multiple days and I want to monitor the current error log.

for /f "delims=" %%a in (' dir /b /a-d /od *.log ') do set "latest_file=%%a"

我现在知道这不是你的目标。

您似乎使用与正在处理的文件相同的日志文件名。

你有 delims=; 没有的地方；在您的日志片段中。

您正在两个循环中重用 %%a 。

set file=E:\logs\ihs\Default\error.log.%Month%.%Today%.%Year%

echo Polling %file% at %Time% >> %log%
for /f "usebackq delims=;" %%a in (`dir /b   E:\logs\ihs\Default\error.log.%Month%.%Today%.%Year%`) do (
    echo Checking now >> %log%
    for /f "tokens=8,9 delims= " %%a in     (E:\logs\ihs\Default\error.log.%Month%.%Today%.%Year%) do (
于 2013-06-23T13:19:22.303 回答
2

您在 FOR 循环中使用了特定文件，因此不需要其中两个。第一个只是确认文件存在。这更容易，更有效地完成：

if exist "E:\logs\ihs\Default\error.log.%Month%.%Today%.%Year%" ( ... )

其他人说你在使用%%a两个循环时都有问题。实际上，在嵌套循环中重用字符并没有错。但是您的内部循环无法访问外部循环值。鉴于您的内部循环 DO 引用%%j，我怀疑您打算使用内部循环%%i而不是%%a.

您的逻辑是错误的，因为您的循环正在处理所有行，而它应该只处理包含“ rdy ”的行。FIND 或 FINDSTR 可用于有效过滤掉不需要的行。

您永远不应将自己的值分配给名为 TIME 的变量（请注意，变量名不区分大小写）。这样做可以防止您以后访问动态时间值。

我还没有弄清楚当外循环工作时什么会阻止进入你的内循环。但我会重组你的整个代码。

我不会从当前日期派生日志文件的名称，而是按日期/时间顺序列出所有日志文件，并使用 FOR /F 捕获找到的最后一个文件。

然后我会使用另一个 FOR /F 来解析 FINDSTR 搜索“rdy”的输出

@echo off
setlocal
set "log=E:\scripts\busycheckalert.log"
set "checkTime=%time:~0,5%"
pushd "E:\logs\ihs\Default"

set "currentLog="
for /f "delims=" %%F in ('dir /b /a-d /od "error.log.*"') do set "currentLog=%%F"
if defined currentLog (
  >>"%log%" echo Polling %currentLog% at %checkTime%
  for /f "tokens=9" %%A in ('findstr /c:" rdy " "%currentLog%"') do (
    if %%A leq 200 >>"%log%" echo Error at %time%: Ready threshold exceeded in %currentLog% 
  )
) else  >>"%log%" echo No log found at %checkTime%"

popd
于 2013-06-23T15:55:44.947 回答