sql - 存储过程更新两个具有不同 id 的表

Question

我有这样的存储过程：

alter procedure [dbo].[delivary] @dedate nvarchar(100), 
                                 @carid nvarchar(100), 
                                 @transid integer as
begin
    select t.transactID 
      from Transaction_tbl t 
     where t.TBarcode = @carid
    update Transaction_tbl 
       set DelDate = '' + @dedate + '', Status=5 
     where TBarcode = @carid
    update KHanger_tbl 
       set Delivered=1 
     where transactid=@transid
end

我能够更新我的交易表。我还想KHanger_table用TransactID匹配的@carid.

我怎么能这样做？

Answer 1

有两种方法可以做到：

首先检索您的 transactID 并将其存储在变量中：

alter procedure [dbo].[delivary] @dedate nvarchar(100), 
                                 @carid nvarchar(100)as
begin
    declare @transid int
    select @transid = t.transactID 
      from Transaction_tbl t 
     where t.TBarcode = @carid

    update Transaction_tbl 
       set DelDate = '' + @dedate + '', Status=5 
     where TBarcode = @carid

    update KHanger_tbl 
       set Delivered=1 
     where transactid=@transid
end

你有关系更新：

alter procedure [dbo].[delivary] @dedate nvarchar(100), 
                                 @carid nvarchar(100) as
begin
    update Transaction_tbl 
       set DelDate = '' + @dedate + '', Status=5 
     where TBarcode = @carid

    update KHt
      set KHt.Delivered=1
    from KHanger_tbl as KHt
      inner join Transaction_tbl t
        on KHt.transactionid = t.transactID
    where t.TBarcode = @carid
end

Answer 2

它应该是

alter procedure [dbo].[delivary] 
    (@dedate nvarchar(100), 
    @carid nvarchar(100))
    AS
    begin
        DECLARE @transactID int;
        SET @transactID = (select t.transactID 
          from Transaction_tbl t 
         where t.TBarcode = @carid);

        update Transaction_tbl 
           set DelDate = '' + @dedate + '', Status=5 
         where TBarcode = @carid

        update KHanger_tbl 
           set Delivered=1 
         where transactid=@transactID
    end

Answer 3

这是另一种（较短的）方法：

alter procedure [dbo].[delivary] 
(@dedate nvarchar(100), 
@carid nvarchar(100))
AS
begin
    DECLARE @transactID int;

    update Transaction_tbl 
       set DelDate = @dedate, Status=5, @transactID = transactID 
     where TBarcode = @carid

    update KHanger_tbl 
       set Delivered=1 
     where transactid=@transactID
end

此外，您可能希望在事务中进行 2 次更新，因此要么都成功，要么根本不成功。