1

我想要合并相同的元素，例如：

<Root>
    <row>
        <WID>10</WID>
        <word>Bob</word>
        <SID>2</SID>
        <Ah>1</Ah>
    </row>
    <row>
        <WID>5941</WID>
        <word>Jany</word>
        <SID>2</SID>
        <Ah>1</Ah>
    </row>
</Root>

结果是：

<span>Bob Jany</span>

我写了这个，但它是错误的：

<xsl:choose> 
<xsl:when test = "Ah[text()]=Ah[text()]"> 
         <span>
             <xsl:value-of select="./word"/>
         </span>
</xsl:when> 
</xsl:choose>
4

2 回答 2

2

使用分组，使用 XSLT 2.0（由 Saxon 9 或 AltovaXML 或 XmlPrime 运行）就像

<xsl:stylesheet version="2.0" 
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output indent="yes"/>

<xsl:template match="Root">
  <xsl:copy>
    <xsl:for-each-group select="row" group-by="Ah">
      <span><xsl:value-of select="current-group()/word"/></span>
    </xsl:for-each-group>
  </xsl:copy>
</xsl:template>

</xsl:stylesheet>

当我在输入样本上使用 Saxon 9.5 HE 应用上述样式表时

<Root>
    <row>
        <WID>10</WID>
        <word>Bob</word>
        <SID>2</SID>
        <Ah>1</Ah>
    </row>
    <row>
        <WID>5941</WID>
        <word>Jany</word>
        <SID>2</SID>
        <Ah>1</Ah>
    </row>
</Root>

我得到结果

<Root>
   <span>Bob Jany</span>
</Root>
于 2013-06-22T17:00:10.863 回答
1

使用 Muenchian 分组方法的 XSLT 1.0 解决方案：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kRowByAh" match="row" use="Ah" />
 <xsl:template match="row[generate-id()=generate-id(key('kRowByAh', Ah)[1])]">
  <span>
    <xsl:value-of select="word"/>
    <xsl:for-each select="key('kRowByAh', Ah)[position() > 1]">
     <xsl:value-of select="concat(' ', word)"/>
    </xsl:for-each>
  </span>
 </xsl:template>
 <xsl:template match="text()"/>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<Root>
    <row>
        <WID>10</WID>
        <word>Bob</word>
        <SID>2</SID>
        <Ah>1</Ah>
    </row>
    <row>
        <WID>5941</WID>
        <word>Jany</word>
        <SID>2</SID>
        <Ah>1</Ah>
    </row>
</Root>

产生了想要的正确结果：

<span>Bob Jany</span>
于 2013-06-23T16:46:00.093 回答