8

我有一个日期（作为字符串）被提交。我想将此映射到命令对象。我环顾四周，发现没有很好的资源来说明如何在命令对象中将此映射到实际日期。

如果我要在控制器本身中执行此操作，我可以执行以下操作，但这不允许我轻松映射到我的命令对象。

def endDate = params.date('endDate', 'MM/dd/yyyy')

对于我的命令对象，我能得到的最接近的是覆盖日期对象的 getter 和 setter。两者都需要被覆盖，否则不使用设置器。这是我第一次尝试的（将字符串设置为日期，但获取日期）。所以这不使用setter：

@grails.validation.Validateable
class TaskCreateCommand {

    Date startDate


    public void setStartDate(String dateStr){
        this.start = Date.parse('MM/dd/yyyy', dateStr)
    }

}

这不会产生任何运行时问题，但没有用，因为我无法提取实际的 Date 对象。

@grails.validation.Validateable
class TaskCreateCommand {

    Date startDate


    public void setStartDate(String dateStr){
        this.start = Date.parse('MM/dd/yyyy', dateStr)
    }

    public String getStartDate(){
        return start.toString()
    }
}
4

3 回答 3

13

如果您使用 Grails 2.3 或更高版本，您可以在 Config.groovy 中添加多种自定义日期格式以进行数据绑定

grails.databinding.dateFormats = ["MM/dd/yyyy"]

然后当 Grails 尝试将请求参数绑定到 Command 对象属性时，将在解析请求参数中的日期字符串时尝试您的自定义格式，例如。

class MyController {
    def myAction(MyCommandObject cmd) {
        println cmd.date
        println cmd.date.class
    }
}

class MyCommandObject {
    Date date
}

然后当你打例如。

http://localhost:8080/myController/myAction?date=12/13/2013

你应该看到类似 ->

Fri Dec 13 00:00:00 EST 2013
class java.util.Date

在您的控制台上。

于 2014-01-30T11:39:02.200 回答
6

巧合的是，我今天也在研究同样的问题，并从@Don 那里得到了这个答案。我能够将日期正确绑定到命令对象。

@Validateable
class BookCommand {
    String name
    Date pubDate
    Integer pages
}

//Controller
def index(BookCommand cmd) {
        println cmd.name
        println cmd.pages
        println cmd.pubDate

        render "Done"
    }

//src/groovy
class CustomDateEditorRegistrar implements PropertyEditorRegistrar {
    public void registerCustomEditors(PropertyEditorRegistry registry) {
        String dateFormat = 'yyyy/MM/dd'
        registry.registerCustomEditor(Date, new CustomDateEditor(new SimpleDateFormat(dateFormat), true))
    }
}

//URL
http://localhost:8080/poc_commandObject/book?name=Test&pages=10&pubDate=2012/11/11

//Println
Test
10
Sun Nov 11 00:00:00 EST 2012
于 2013-06-21T20:22:08.417 回答
2

如果使用正确的@BindingFormat，对我有用。例子：

import grails.databinding.BindingFormat
class DateRangeFilter {
    String fieldName
    @BindingFormat('yyyy-MM-dd')
    Date from
    @BindingFormat('yyyy-MM-dd')
    Date to 
}
于 2019-08-16T06:28:34.320 回答