1

我正在使用 Delphi 加载一个 dll（我在 Delphi XE-3 中创建），以便与一些 C 代码进行交互。我的问题是弄清楚为什么我的数组没有被传递给 c 函数——它们是唯一不传递的。delphi 文件（简化）如下所示：

program CallcCode
uses
  SysUtils, Windows, 
  DLLUnit in 'DLLUnit.pas'; // Header conversion

var
  DLLHandle: cardinal;
  n: Integer;
  A: TArray<Integer>;
  result1: Integer; 

begin
  // Initialize each Array
  SetLength(A,n);
  A[0] = ...;

  // Load the DLL (and confirm its loaded)
  DLLhandle := LoadLibrary('dllname.dll');
    if DLLhandle <> 0 then
      begin
       result1 := dll_func1(n,A); // A and B are not passed correctly
    end
  FreeLibrary(DLLHandle);
end.

我第一次成功“Trace into” dll_func1，进入DLLUnit，它有：

const
  nameofDLL = 'dllname';
function dll_func1(n: Integer; A: TArray<Integer>): Integer; cdecl; external nameofDLL;

再次“Tracing-into”，我到达了 c 文件，它仍然具有正确的 n 和 DLLdefs 值，但是 A（在“局部变量”标题下）变成了：

[-]  A       :(Aplha-Numeric)
    ..[0]    0 (0x00000000)

我知道我至少可以正确访问 DLL（希望如此），因为其他函数调用可以正常工作，并且我能够毫无问题地跟踪到 dll_func1.c 文件。我尝试将功能更改为

function dll_func1(n: Integer; A: PInteger): Integer; cdecl; external nameofDLL;
...
result1 := dll_func1(n,PInteger(A))

或者

function dll_func1(n: Integer; A: PInteger): Integer; cdecl; external nameofDLL;
...
result1 := dll_func1(n,@A[0])

（同时使用 TArray 和整数或 A 数组）但没有变化，这让我相信这与我没有看到的问题有关。整个事情编译并运行，但由于 TArray 失败，结果 1 不正确。关于出了什么问题的任何想法？

编辑C 中的函数为：

int dll_func1(int n, int A [])
4

1 回答 1

4

您的问题包含外部函数的两个 Delphi 声明。其中之一TArray<T>用作参数。那是完全错误的。不要那样做。您不能将 Delphi 动态数组用作互操作类型。原因是这TArray<T>是一个复杂的托管类型，只能由 Delphi 代码创建和使用。

您需要按照我在下面执行的操作，并且正如我在对您之前的问题的回答中所解释的那样，并将数组参数声明为指向元素类型的指针。例如, PInteger,PDouble等。

这里有很多混乱和不必要的复杂性。您需要的是最简单的示例，该示例显示如何将数组从 Delphi 代码传递到 C 代码。

这里是。

C代码

//testarray.c

void printDouble(double d); // linker will resolve this from the Delphi code

void test(double *arr, int count)
{
    int i;
    for (i=0; i<count; i++)
    {
        printDouble(arr[i]);
    }
}

德尔福代码

program DelphiToC;

{$APPTYPE CONSOLE}

uses
  Crtl;

procedure _printDouble(d: Double); cdecl;
begin
  Writeln(d);
end;

procedure test(arr: PDouble; count: Integer); cdecl; external name '_test';

{$L testarray.obj}

var
  arr: TArray<Double>;

begin
  arr := TArray<Double>.Create(1.0, 2.0, 3.0, 42.0, 666.0);
  test(PDouble(arr), Length(arr));
  Readln;
end.

例如，使用 Borland C 编译器编译 C 代码，如下所示：

bcc32 -c testarray.c

输出是：

1.00000000000000E+0000
 2.00000000000000E+0000
 3.00000000000000E+0000
 4.20000000000000E+0001
 6.66000000000000E+0002

请注意，我静态链接到 C 代码，因为这对我来说更容易。如果将 C 代码放在 DLL 中，则不会有太大变化。

结论是，我在对你之前的回答中给你的代码是正确的，我在这里重复一遍。该方法成功地将数组从 Delphi 代码传递给 C。看起来您的诊断和调试有误。

您只是在检查A[0]，因此您只看到一个值也就不足为奇了。如果您只看A[1], A[2], ... ，A[n-1]您会发现所有值都被正确传递。或者您的调试可能是对用作TArray<T>参数的外部函数的错误声明进行的。

于 2013-06-21T18:31:36.777 回答