sparql - 语义网、数据类型和 sparql。（返回类型是否任意）

Question

我发现语义网是动态类型的！例如，我一直在查询生日，直到现在才找到xsd:Integers。但是，现在我xsd:date在查询另一个人时收到了一个。当从静态类型语言中使用时，您如何处理这个问题？

Answer 1

根据DBpedia wiki 的第4.3 节信息框数据dbpprop，在命名空间 ( http://dbpedia.org/property/) 中使用属性的三元组更脏：

因此，只有当您的应用程序需要完全覆盖所有 Wikipeda 属性并且您准备好接受相对嘈杂的数据时，您才应该使用 infobox 数据集。

dbpedia-owl您将使用( http://dbpedia.org/ontology/) 命名空间中的属性获得更加一致的数据：

信息框本体中的实例数据比信息框数据集更清晰、结构更好

例如，如果您使用 获取 20 个生日dbprop:dateOfBirth，您将获得整数和日期：

SELECT distinct ?date WHERE { 
  ?x dbpprop:dateOfBirth ?date 
}
LIMIT 10

SPARQL 结果

date
"1908"^^<http://www.w3.org/2001/XMLSchema#int>
1946-03-14
1951-06-15
"1984"^^<http://www.w3.org/2001/XMLSchema#int>
1878-11-09
"24"^^<http://www.w3.org/2001/XMLSchema#int>
"21"^^<http://www.w3.org/2001/XMLSchema#int>
"2"^^<http://www.w3.org/2001/XMLSchema#int>
"14"^^<http://www.w3.org/2001/XMLSchema#int>
1922-02-10

使用dbpedia-owl:birthDate给出更一致的结果：

SELECT distinct ?date WHERE { 
  ?x dbpedia-owl:birthDate ?date 
}
LIMIT 10

SPARQL 结果

date
0001-01-01
0001-03-12
0005-02-27
0012-08-31
0012-12-07
0015-09-24
0016-09-16
0019-05-26
0019-11-25
0030-11-08

也就是说，数据中仍然存在一些噪音。例如，这里有一个查询，它告诉我们对象dbpedia-owl:birthDate具有哪些数据类型，以及对于每种类型，dbpedia-owl:birthDate具有该类型对象的次数，以及显示为 对象的该类型的示例对象dbpedia-owl:birthDate。

SELECT ?datetype (COUNT(?date) as ?numberOfType ) (SAMPLE(?date) as ?exampleDate )WHERE { 
  [] dbpedia-owl:birthDate ?date .
  BIND ( datatype( ?date ) as ?datetype )
}
GROUP BY ?datetype
ORDER BY DESC(?numberOfType)

SPARQL 结果

datetype                                    numberOfType  exampleDate
http://www.w3.org/2001/XMLSchema#date       608771        0001-01-01
http://www.w3.org/2001/XMLSchema#gMonthDay    1185        "--02-29"^^<http://www.w3.org/2001/XMLSchema#gMonthDay>
http://www.w3.org/2001/XMLSchema#string        246        "--01-01"^^<http://www.w3.org/2001/XMLSchema#gMonthDay>

大多数日期都是xsd:dates。我不确定为什么 anxsd:gMonthDay出现一个xsd:string.