sas - SAS - 创建具有滞后的不同独立变量的组合

Question

我想在使用变量名称（例如 VarA、VarB、VarC）形成的数据集（在 SAS 中）中创建动态条目，每个变量的延迟最多为 4。

输入数据集 HAVE 有这些信息（列名是变量和值）：

Variables Values

VarA          0

VarB          0

VarC          0

Lags          4

并且输出数据集 WANT 应该如下所示（Var1、Var2 和 Var3 是动态列名，即将 1、2、3 附加到任何字符串 Var）

Var1     Var2      Var3

VarA     VarB      VarC 

VarA1    VarB1     VarC1

..

VarA4    VarB4     VarC4

目的是对 HAVE 数据集中的任意数量的变量进行这项工作。

谢谢

Answer 1

以下代码返回您想要的。请根据您的需要进行修改。

/*sample input dataset*/
data have;
input Variables $ Values;
datalines;
VarA 0
VarB 0
VarC 0
Lags 4
;
run;
/*get the no. of lags form the input dataset*/
proc sql noprint;
select Values into :num_of_lags from have where upcase(variables)='LAGS';
quit;
/*transpose the input dataset such that the VarA, VarB, VarC are put in columns Var1, Var2, & Var3 respectively*/
/*have_t, the transposed dataset only has 1 row.*/
proc transpose data = have out =  have_t(drop = _name_) prefix = var;
where upcase(variables)  ne 'LAGS';
var variables;
run;
/*replicate the 1 row in have_t num_of_lags times*/
data pre_want;
    set have_t;
    array myVars{*} _character_;
        do j= 1 to &num_of_lags+1;
            do i = 1 to dim(myVars);
            myVars[i]=myVars[i];
            end;
        output;
    end;
run;
/*final dataset*/
data want;
set pre_want;
array myVars{*} _character_;
if _N_>1 then do;
do i = 1 to dim(myVars);
        myVars[i]=compress(myVars[i]!!_n_-1);
    end;
end;
drop i j;
run;
proc print data = want; run;

输出：

var1  var2  var3 
VarA  VarB  VarC 
VarA1 VarB1 VarC1 
VarA2 VarB2 VarC2 
VarA3 VarB3 VarC3 
VarA4 VarB4 VarC4