1

我正在使用 SampleDataEvent 用 AS3 制作正弦波声音。我可以很容易地制作一个纯正弦波，但是如果我尝试扫过频率，我会得到可怕的爆裂声。这是我正在使用的代码 - 任何帮助都会很棒。

    package
    {
        import flash.display.*;
        import flash.events.*;
        import flash.media.*;
        import flash.utils.Timer;

        public class DynamicSound extends Sprite
        {
            private var sound:Sound;
            private var noise:Number = 0;
            private var f:Number = 1000;
            private var v:Number = 1;
            private var sweepDown:Boolean = true;

            // make the sound
            public function DynamicSound():void
            {
                sound = new Sound();
                sound.addEventListener(SampleDataEvent.SAMPLE_DATA, onCallback);
                sound.play();
                sweep();
            }

            // create the sinewave
            private function onCallback(e:SampleDataEvent):void
            {
                for (var i:int = 0; i < 8192; i++)
                {
                    noise += 1;
                    var sampleNumber = noise;
                    e.data.writeFloat(v * Math.sin(sampleNumber * f / 44100));
                    e.data.writeFloat(v * Math.sin(sampleNumber * f / 44100));

                }
            }

            // sweep up and down frequency
            private function sweep() {
                var timer:Timer = new Timer(100);
                timer.addEventListener(TimerEvent.TIMER, onTimer);
                timer.start();
                function onTimer(event:TimerEvent):void
                {
                    if(sweepDown){
                        f--;
                    } else {
                        f++;
                    }
                    if (f <=600 ){
                        sweepDown = false;
                    }
                    if (f >= 1000) {
                        sweepDown = true;
                    }
                trace(f);

                }
            }
        }
    }
4

2 回答 2

2

我相信问题出在方法上，扫描需要是渐进的，当你踩它时，你会在声波中产生一个突然的变化，这被解释为一个短暂的高频信号——砰砰声或咔嗒声。我建议您进行此调制的方式是在回调循环内。

设置目标频率（dF）和当前频率（cF），而不是在循环内进行突变设置cF = cF*0.8 + dF*0.2，这应该消除突变并使其发生在多个样本中。

于 2013-06-19T17:01:00.027 回答
0 
//When the frequency changes, the phase will also change. 
//By adjusting the phase, there will no longer be horrible popping.

//This will solve the problem:

var f_old:Number = f;                    
noise=noise*f_old/f;  f_old=f; 


//Copy/paste in the first frame of the main timeline:

          import flash.display.*;
          import flash.events.*;
          import flash.media.*;
          import flash.utils.Timer;

              var sound:Sound;
              var noise:Number = 0;
              var f:Number = 1000;
              var v:Number = 1;
              var sweepDown:Boolean = true;
var f_old:Number = f;

                  // make the sound
                  sound = new Sound();
                  sound.addEventListener(SampleDataEvent.SAMPLE_DATA, onCallback);
                  sound.play();
                  sweep();

              // create the sinewave
              function onCallback(e:SampleDataEvent):void
              {
                  for (var i:int = 0; i < 8192; i++)
                  {
                      noise += 1;
                      var sampleNumber = noise;
                      e.data.writeFloat(v * Math.sin(sampleNumber * f / 44100));
                      e.data.writeFloat(v * Math.sin(sampleNumber * f / 44100));

                  }
              }

              // sweep up and down frequency
              function sweep() {
                  var timer:Timer = new Timer(100);
                  timer.addEventListener(TimerEvent.TIMER, onTimer);
                  timer.start();
                  function onTimer(event:TimerEvent):void
                  {
                      if(sweepDown){
                          f--;
                      } else {
                          f++;
                      }
                      if (f <=600 ){
                          sweepDown = false;
                      }
                      if (f >= 1000) {
                          sweepDown = true;
                      }
                  trace(f);

//Keep the instantaneous value at the same level:
noise=noise*f_old/f;
f_old=f;

                  }
              }         

//Explanation:
//The instantaneous value of the wave must not change at the moment of frequency change. 
//In this script the instantaneous value is determined by:  
//v * Math.sin(sampleNumber * f / 44100)
//noise = sampleNumber  →  v * Math.sin(sampleNumber * f / 44100) = v * Math.sin(noise * f / 44100)
//Keep the instantaneous value at the same level:
//v * Math.sin(noise_new * f / 44100) = v * Math.sin(noise* f_old / 44100) 
//Cancel out v*Math.sin and /44100   →
//noise_new * f = noise* f_old  →  noise_new = noise*f_old/f
//Because noise gets a new value, there is no need to give noise the name noise_new.  →
//noise = noise*f_old/f
于 2018-12-18T00:54:46.437 回答