1

我正在使用CMS制作网站，在主页中我需要随机获取一些图片和说明，每次刷新页面时我都需要获取新节点。

这就是我在 XSL 中调用节点的方式：

<xsl:for-each select ="TSPRoot/Blocks/Block[@ID=134]/Articles/Article[position() &lt; 4]">
          <div class="layout-08">
            <a class="title" href="detailed.aspx?id={ID}">
              <xsl:choose >
                <xsl:when test ="string-length(ImageURL) > 0">
                  <img src="_handlers/resizeimage.ashx?src={ImageURL}&amp;height=149&amp;width=206" title="{Headline}"/>
                </xsl:when>
                <xsl:otherwise>
                  <img src="_frontend/ux/images/en_logo.png" width="206" height="149" title="{Headline}"/>
                </xsl:otherwise>
              </xsl:choose>
            </a>
            <div class="bg">
              <a href="detailed.aspx?id={ID}"><xsl:value-of select ="Headline"/></a>
            </div>
          </div>
        </xsl:for-each>

这将获得最新的 (3) 个节点，每次刷新时我都需要随机 (3) 个节点。

4

1 回答 1

0

我只会给你一些可能的解决方案的想法。从技术上讲，XSLT 不提供随机数方法。然而，这个问题至少可以通过三种不同的方式来解决：

  1. 在执行 XSLT 模板之前在 Java/C#/PHP 代码中生成伪随机数，并将生成的数字作为 XSLT 参数传递。

  2. 使用扩展功能： http ://exslt.org/random/functions/random-sequence/index.html

  3. 使用current-dateTime()(XSLT 2.0) 函数作为随机数过程的种子。通过几个字符串和数学运算，您可以将其转换为所需的准随机数。我认为对于您的需求，这个解决方案就足够了。

编辑 - 广告 3。

我对这个想法做了一些实验。我已经创建了一些示例代码。我知道这段代码会生成一系列真正的伪随机数，但对于像问题中这样的简单网页来说，它可能就足够了。

以下 XSLT：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions" xmlns:rnd="http://whatever.org/random">
    <xsl:output indent="yes" />
    <xsl:function name="rnd:pseudoRandomInternal">
        <xsl:param name="numSeed" as="xs:decimal"/>
        <xsl:variable name="squareSeed" select="xs:string($numSeed*$numSeed)"/>
        <xsl:variable name="oneDivSeed" select="substring($squareSeed, 3, string-length($squareSeed) - 3)"/>
        <xsl:variable name="cc" select="if (string-length($oneDivSeed) > 6) then 
            substring($oneDivSeed, string-length($oneDivSeed) - 6) else 
            $oneDivSeed"/>
        <xsl:value-of select="xs:decimal($cc)"/>
    </xsl:function>
    <xsl:function name="rnd:pseudoRandom" as="xs:decimal*">
        <xsl:param name="range" as="xs:integer"/>

        <xsl:choose>
            <xsl:when test="$range = 1">
                <xsl:variable name="seed" select="substring(xs:string(current-time()), 1, 12)" as="xs:string"/>
                <xsl:variable name="numSeed" select="xs:decimal(translate($seed, ':.+-', ''))"/>
                <xsl:sequence select="(rnd:pseudoRandomInternal($numSeed))" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:variable name="subSequence" select="rnd:pseudoRandom($range - 1)"/>
                <xsl:variable name="newValue" select="rnd:pseudoRandomInternal($subSequence[1])" as="xs:decimal*"/>
                <xsl:sequence select="($newValue, $subSequence)"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:function>
    <xsl:template match="/">
        <xsl:variable name="rr" select="rnd:pseudoRandom(10)" as="xs:decimal*"/>

        <output>
        <xsl:for-each select="$rr">
            <item>
                <xsl:value-of select=". * 3 mod 11" />
            </item>
        </xsl:for-each>
        </output>
    </xsl:template>
</xsl:stylesheet>

生成以下输出：

<output>
    <item>10</item>
    <item>9</item>
    <item>6</item>
    <item>9</item>
    <item>9</item>
    <item>10</item>
    <item>3</item>
    <item>5</item>
    <item>9</item>
    <item>4</item>
</output>
于 2013-06-20T10:06:41.597 回答