1

我正在使用 Leiningen 和 Clojure，在我的一生中，我无法理解为什么 Clojure 使得正确导入命名空间变得如此困难。这是以下错误

这是我的core.clj文件中的内容：

; namespace macro
(ns animals.core
  (:require animals.animal)
  (:use animals.animal)
  (:import (animals.animal Dog))
  (:import (animals.animal Human))
  (:import (animals.animal Arthropod))
  (:import (animals.animal Insect)))

; make-animals will create a vector of animal objects
(defn make-animals []
  (conj []
        (Dog. "Terrier" "Canis lupis familiaris")
        (Human. "Human" "Homo sapiens")
        (Arthropod. "Brown Recluse" "Loxosceles reclusa")
        (Insect. "Fire Ant" "Solenopsis conjurata")))

; print-animals will print all the animal objects
(defn print-animals [animals]
  (doseq [animal animals]
    (println animal)))

; move-animals will call the move action on each animal
(defn move-animals [animals]
  (doseq [animal animals]
    (animals.animal/move animal)))

; entry to main program
(defn -main [& args]
  (let [animals make-animals]
    (do
      (println "Welcome to Animals!")
      (println "-------------------")
      (print-animals animals))))

然后，在 REPL 中，我输入以下内容（在lein项目的 src/ 目录中）：

user> (require 'animals.core)
nil
user> (animals.core/-main)
ClassNotFoundException animals.core  java.net.URLClassLoader$1.run (URLClassLoader.java:202)

好吧……什么？为什么？

作为参考，这是我的文件animal.clj也在animals目录中：

(ns animals.animal)

(defprotocol Animal
  "A simple protocol for animal behaviors."
  (move [this] "Method to move."))

(defrecord Dog [name species]
  Animal
  (move [this] (str "The " (:name this) " walks on all fours.")))

(defrecord Human [name species]
  Animal
  (move [this] (str "The " (:name this) " walks on two legs.")))

(defrecord Arthropod [name species]
  Animal
  (move [this] (str "The " (:name this) " walks on eight legs.")))

(defrecord Insect [name species]
  Animal
  (move [this] (str "The " (:name this) " walks on six legs.")))
4

1 回答 1

2

-main将您的代码粘贴到一个新的 Leiningen 项目中后，由于: (let [animals make-animals] ...)should be中的拼写错误，我得到了一个不同的错误(let [animals (make-animals)] ...)。通过此更改，一切正常：

user=> (require 'animals.core)
nil
user=> (animals.core/-main)
Welcome to Animals!
-------------------
#animals.animal.Dog{:name Terrier, :species Canis lupis familiaris}
#animals.animal.Human{:name Human, :species Homo sapiens}
#animals.animal.Arthropod{:name Brown Recluse, :species Loxosceles reclusa}
#animals.animal.Insect{:name Fire Ant, :species Solenopsis conjurata}
nil

lein repl顺便说一句，只要它在项目目录中的某个位置，您从哪里调用并不重要。

我冒昧地猜测，当您第一次尝试使用require它时，您的名称空间有问题，现在由于您的 REPL 中的某些名称空间加载状态，它不会加载。您可能想尝试(require :reload 'animals.core)，如果这不起作用，请重新启动您的 REPL。ClassNotFoundException（如果你再次遇到它，你也可以将整个 REPL 交互粘贴到某个地方。）

另外，关于您的ns表格：

  1. 您不应该同时:require使用:use相同的命名空间；:use已经:require是了。

  2. 更常见的是使用单个:import子句（实际上，每个子句类型一个子句）；例如，

    (:import (animals.animal Dog Human Arthropod Insect))

    这在 Clojure 中纯粹是一种风格问题，但在 ClojureScript 中，它实际上是语言所要求的。

于 2013-06-16T00:37:33.267 回答