0

我已经从中提取了一个样本xml.com来证明我遇到的问题。

我有这个 XML：

<?xml version="1.0"?>

<!--slightly modified source from xml.com -->

<winelist xmlns="urn:somesite:api:base">

    <wine grape="Chardonnay">
        <winery>Lindeman's</winery>
        <product>Bin 65</product>
        <year>1998</year>
        <prices>
        <list>6.99</list>
            <discounted>5.99</discounted>
            <case>71.50</case>
        </prices>
    </wine>

    <wine grape="Chardonnay">
        <winery>Benziger</winery>
        <product>Carneros</product>
        <year>1997</year>
        <prices>
            <list>10.99</list>
            <discounted>9.50</discounted>
            <case>114.00</case>
        </prices>
    </wine>

    <wine grape="Cabernet">
        <winery>Duckpond</winery>
        <product>Merit Selection</product>
        <year>1996</year>
        <prices>
            <list>13.99</list>
            <discounted>11.99</discounted>
            <case>143.50</case>
        </prices>
    </wine>

    <wine grape="Chardonnay">
        <winery>Kendall Jackson</winery>
        <product>Vintner's Reserve</product>
        <year>1998</year>
        <prices>
            <list>12.50</list>
            <discounted>9.99</discounted>
            <case>115.00</case>
        </prices>
    </wine>

</winelist>

而这个 XSL：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

    <xsl:template match="winelist">
        <xsl:copy>
            <xsl:apply-templates>
                <xsl:sort data-type="number" select="prices/discounted"/>
            </xsl:apply-templates>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="*">
        <xsl:copy>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

我正在尝试wine按折扣价对元素进行排序，但转换后的 XML 仍然未排序，除非我首先从酒单中删除名称空间（即，仅使用<winelist>）。

如何修改 XSLT 以便不必手动移除名称空间？

此外，转换后的 XML 中的葡萄酒实体缺少它们的原始grape属性。这些怎么保存？评论也是如此（虽然不是那么重要）。

我可以先使用另一个转换来删除所有命名空间，但我不太喜欢这种两步解决方案，我认为这可能是其他 XML 源问题的根源。

有人可以在这里帮助我吗？

4

2 回答 2

0

您唯一需要做的就是将名称空间添加到 XSLT 并将match="*"模板修改为身份转换。

例子：

<xsl:stylesheet xmlns:x="urn:somesite:api:base" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="x:winelist">
        <xsl:copy>
            <xsl:apply-templates>
                <xsl:sort data-type="number" select="x:prices/x:discounted"/>
            </xsl:apply-templates>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

local-name()命名空间是否未知的示例（使用 Xalan 和 Saxon 6.5.5 测试）：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="*[local-name()='winelist']">
        <xsl:copy>
            <xsl:apply-templates>
                <xsl:sort data-type="number" select="*[local-name()='prices']/*[local-name()='discounted']"/>
            </xsl:apply-templates>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>
于 2013-06-14T17:06:09.140 回答
-1

首先，要忠实地复制输入 XML，请使用以下内容（称为“身份转换”）：

 <xsl:template match="@*|*|processing-instruction()|comment()">
    <xsl:copy>
      <xsl:apply-templates select="@*|*|text()|processing-instruction()|comment()"/>
    </xsl:copy>
  </xsl:template>

其次，为了让您的匹配器忽略命名空间（如果这是您真正想要做的），您可以按本地名称进行匹配：

<xsl:template match="*[local-name()='winelist']">

或者，您可以让 XSLT 知道名称空间并在该名称空间中显式匹配，这是更常用的方法。您不想这样做的唯一原因是您事先不知道命名空间。

<xsl:stylesheet xmlns:w="urn:somesite:api:base">
...
   <xsl:template match="w:wine">
     ...
于 2013-06-14T17:05:10.560 回答