9

我有这个代码片段，我试图每隔 X 秒将一个字符串推送到服务器，例如：

#!/usr/bin/env perl
use Mojolicious::Lite;
use EV;
use AnyEvent;
use POSIX qw(strftime);

get '/' => sub {
    my $self = shift;

    $self->render('main');
};

websocket '/echo' => sub {
        my $self = shift;
        my $w;
        $w = AE::timer 3, 1, sub {
                    $self->send('Got it');
        };
      #  $self->send(strftime("Server $$: %a %b %e %H:%M:%S %Y", localtime));
};
app->start();

__DATA__
@@ main.html.ep
<html>
<head>
<script src="//ajax.googleapis.com/ajax/libs/jquery/1.10.1/jquery.min.js"></script>
</head>
<body>
<table id="tableID">
<tbody>
</tbody>
</table>
<script type="text/javascript">
var ws = new WebSocket('ws://192.168.1.104:3000/echo');
      ws.onopen = function () {
        alert('Connection opened');
      };
      ws.onerror = function() { alert("Error"); };
      ws.onmessage = function (msg) {
          $("#tableID").find('tbody')
                       .append($('<tr>')
                       .append($('<td>')
                       .text(msg.data)
            )
        );

      };
</script>
</body>
</html>

AFAIK Mojo 使用IO::Loop了事件循环，我想这应该没问题AnyEvent

这不起作用，我想知道为什么。当我删除 AE 部分并取消注释 simplesend时，我会在浏览器中看到结果。

PS：只是在一些项目中尝试使用 WebSockets 和 Mojo，我需要同时使用 Mojo 和 AnyEvent + WebSockets

4

1 回答 1

7

问题似乎是在 GET 连接升级到 websocket 之前尝试发送消息。我仍在努力追查它，与此同时，这很有效。

#!/usr/bin/env perl
use Mojolicious::Lite;
use EV;
use AnyEvent;
#use POSIX qw(strftime);

get '/' => sub {
    my $self = shift;

    $self->render('main');
};

websocket '/echo' => sub {
        my $self = shift;
        my $w;

        $self->on(finish => sub { Mojo::IOLoop->remove($w) });
      #  $self->send(strftime("Server $$: %a %b %e %H:%M:%S %Y", localtime));

        $w = Mojo::IOLoop->recurring( 1 => sub{
                    $self->send('Got it');
        });
};
app->start();

__DATA__
@@ main.html.ep
<html>
<head>
<script src="//ajax.googleapis.com/ajax/libs/jquery/1.10.1/jquery.min.js"></script>
</head>
<body>
<table id="tableID">
<tbody>
</tbody>
</table>
<script type="text/javascript">
var ws = new WebSocket("<%= url_for('echo')->to_abs %>");
      ws.onopen = function () {
        alert('Connection opened');
      };
      ws.onerror = function() { alert("Error"); };
      ws.onmessage = function (msg) {
          $("#tableID").find('tbody')
                       .append($('<tr>')
                       .append($('<td>')
                       .text(msg.data)
            )
        );

      };
</script>
</body>
</html>

请注意，在我的示例中，调试输出显示101 switching protocols，而您的示例尝试自动渲染echo.html.ep。

我还更改了模板以生成 websocket url。

更新：

似乎为了连接到 websocket，必须订阅一个事件。在此示例中，我订阅了完成事件，无论如何您都希望这样做以停止计时器。

#!/usr/bin/env perl
use Mojolicious::Lite;
use EV;
use AnyEvent;
#use POSIX qw(strftime);

get '/' => sub {
    my $self = shift;

    $self->render('main');
};

websocket '/echo' => sub {
        my $self = shift;
        my $w;
        $w = AE::timer 3, 1, sub {
                    $self->send('Got it');
        };
        $self->on(finish => sub{ undef $w });
      #  $self->send(L<Mojolicious::Controller/strftime("Server $$: %a %b %e %H:%M:%S %Y", localtime));
};
app->start();

更新 2：

为了澄清问题，SRI在 Mojolicious 中添加了以下文档：

当您以 101 响应状态响应 WebSocket 握手时，连接就会建立，如果您使用“on”订阅事件或立即使用“send”发送消息，则会自动发生这种情况。

这解释了这种情况。原始代码既不订阅事件也不send立即订阅。在几乎所有情况下，您至少执行两者中的一项，但在这种情况下:-)

于 2013-06-14T17:13:58.597 回答