1

我有以下函数用于循环浏览 PDF 文件的目录，并为每个文件创建一个缩略图：

<cffunction name="createThumbnails" returntype="Void" output="false">
    <cfscript>
        //  CONSTANTs
        var _PDF_PATH = APPLICATION.PDFSource & "\PDFs";

        //  Set defaults for private variables
        var _qPDFDir = QueryNew("");
        var _documentId = 0;
        var _sourceFilePath = "";
        var _sku = "";
        var _tempImageFilePath = "";
    </cfscript>

    <!--- Retrieve a list of file names in the directory of unprocessed PDF files --->
    <cfdirectory
        action="list"
        directory="#_PDF_PATH#"
        name="_qPDFDir"
        filter="*.pdf"
        type="file"
        sort="datelastmodified DESC"
        listinfo="name" />

    <!--- Loop through the list of file names in the directory of unprocessed non-PDF files --->
    <cfloop query="_qPDFDir" endrow="500">
        <cfset _sourceFilePath = _PDF_PATH & "\" & name />

        <cfif FileExists(_sourceFilePath) AND IsPDFFile(_sourceFilePath)>
            <cftry>
                <cfpdf
                    action="thumbnail"
                    source="#_sourceFilePath#"
                    destination="#APPLICATION.TempDir#"
                    format="png"
                    scale="100"
                    resolution="high"
                    overwrite="true"
                    pages="1" />

                <cfcatch>
                    <cfscript>
                        FileMove(
                            _sourceFilePath,
                            _PDF_PATH & "\NonFunctioning\"
                            );
                    </cfscript>
               </cfcatch>
            </cftry>

            <cfscript>
                _documentId =
                    REQUEST.UDFLib.File.getFileNameWithoutExtension(name);
                _tempImageFilePath =
                        APPLICATION.TempDir
                    &   "\"
                    &   _documentId
                    &   "_page_1.png";

                if  (FileExists(_tempImageFilePath)) {
                    _sku = getSkuFromDocumentId(_documentId);

                    if  (Len(_sku)) {
                        CreateObject(
                            "component",
                            "cfc.products.Product"
                            ).setClientId(
                                getClientId()
                                ).setId(
                                    _sku
                                    ).createThumbnails(
                                        sourcePath = _tempImageFilePath,
                                        deleteSourceFile = true
                                        );

                        FileMove(
                            _sourceFilePath,
                            APPLICATION.ProcessedPDFDir
                            );
                    }
                }
            </cfscript>
        </cfif>
    </cfloop>

    <cfreturn />
</cffunction>

有些代码不是我想做的——即将文件移动到“NonFunctioning”目录，但这是业务规则所要求的。

我想弄清楚的是，当这个函数运行时如何避免耗尽内存？

使用endrow="500"，它java.lang.OutOfMemoryError: GC overhead limit exceeded在处理大约 148 个文件后出现错误。

当我在任务管理器 (Windows) 中查看 jrun.exe 进程时，我可以看到内存不断增加。

有什么办法可以提高此功能的性能以防止内存被吃掉吗？

4

1 回答 1

0

您在循环中创建对象，每次创建对象 CF 都会保留内存，直到您的页面完成运行，然后释放内存。

  1. 在循环之外实例化您的对象，将其保存在变量中并在循环内重新使用该对象。
  2. 不要一次处理所有文件（如 steve 建议的那样）处理块，然后创建一个新请求（例如 cfhttp）并再次调用您的处理页面，这将释放第一次处理中使用的任何内存。
于 2013-07-29T09:29:31.963 回答