4

SICP 包含 n-queens 解决方案的部分完整示例，通过遍历最后一行中每个可能的皇后位置的树，在下一行中生成更多可能的位置以组合迄今为止的结果，过滤可能性以仅保留那些最新的女王是安全的，并且递归地重复。

这种策略在大约 n=11 后以最大递归误差崩溃。

我已经实现了一种替代策略，该策略从第一列进行更智能的树遍历，从未使用的行列表中生成可能的位置，将每个位置列表连接到尚未使用的行的更新列表中。过滤那些被认为是安全的对，并在这些对上递归映射以用于下一列。这并没有爆炸（到目前为止），但 n=12 需要一分钟， n=13 需要大约 10 分钟才能解决。

(define (queens board-size)
 (let loop ((k 1) (pp-pair (cons '() (enumerate-interval 1 board-size))))
   (let ((position (car pp-pair))
         (potential-rows (cdr pp-pair)))
    (if (> k board-size) 
        (list position)
        (flatmap (lambda (pp-pair) (loop (++ k) pp-pair)) 
         (filter (lambda (pp-pair) (safe? k (car pp-pair))) ;keep only safe
          (map (lambda (new-row) 
                (cons (adjoin-position new-row k position) 
                      (remove-row new-row potential-rows))) ;make pp-pair
           potential-rows))))))) 
;auxiliary functions not listed

不是真的在寻找代码，而是对一个或两个策略的简单解释，它不那么天真，并且与功能性方法相得益彰。

4

2 回答 2

3

我可以为您提供代码的简化，因此它可能会运行得更快一些。我们首先重命名一些变量以提高可读性（YMMV），

(define (queens board-size)
 (let loop ((k 1) 
            (pd (cons '() (enumerate-interval 1 board-size))))
   (let ((position (car pd))
         (domain   (cdr pd)))
    (if (> k board-size) 
        (list position)
        (flatmap (lambda (pd) (loop (1+ k) pd)) 
         (filter (lambda (pd) (safe? k (car pd))) ;keep only safe NewPositions
          (map (lambda (row) 
                (cons (adjoin-position row k position)  ;NewPosition
                      (remove-row row domain))) ;make new PD for each Row in D
               domain)))))))                            ; D

现在，filter f (map g d) == flatmap (\x->let {y=g x} in [y | f y]) d（在那里使用一些 Haskell 语法），即我们可以将the和 the融合为一个：mapfilterflatmap

        (flatmap (lambda (pd) (loop (1+ k) pd)) 
         (flatmap (lambda (row)                   ;keep only safe NewPositions
               (let ( (p (adjoin-position row k position))
                      (d (remove-row row domain)))
                 (if (safe? k p) 
                     (list (cons p d)) 
                     '())))
            domain))

那么，flatmap h (flatmap g d) == flatmap (h <=< g) d（where <=<is right-to-left Kleisli composition operator, but who cares），所以我们可以将两个flatmaps 融合为一个，

        (flatmap 
            (lambda (row)                         ;keep only safe NewPositions
                (let ((p (adjoin-position row k position)))
                  (if (safe? k p)
                    (loop (1+ k) (cons p (remove-row row domain)))
                    '())))
            domain)

所以简化的代码是

(define (queens board-size)
 (let loop ((k        1) 
            (position '())
            (domain   (enumerate-interval 1 board-size)))
    (if (> k board-size) 
        (list position)
        (flatmap 
            (lambda (row)                         ;use only the safe picks
              (if (safe_row? row k position)      ;better to test before consing
                (loop (1+ k) (adjoin-position row k position)
                             (remove-row row domain))
                '()))
            domain))))
于 2013-06-12T08:25:52.580 回答
1

这是我第二次想到的。不确定它是否快得多。不过还是漂亮了一些。

(define (n-queens n)
  (let loop ((k 1) (r 1) (dangers (starting-dangers n)) (res '()) (solutions '()))
    (cond ((> k n) (cons res solutions))
          ((> r n) solutions)
          ((safe? r k dangers) 
           (let ((this (loop (+ k 1) 1 (update-dangers r k dangers) 
                             (cons (cons r k) res) solutions)))
             (loop k (+ r 1) dangers res this)))
          (else (loop k (+ r 1) dangers res solutions)))))

重要的是使用 let 语句来序列化递归，将深度限制为 n。解决方案是向后出现的（可以通过在 r 和 k 上使用 n->1 而不是 1->n 来解决），但是向后的集合与向前的集合是相同的集合。

(define (starting-dangers n)
  (list (list)
        (list (- n))
        (list (+ (* 2 n) 1))))
;;instead of terminating in null list, terminate in term that cant threaten

小的改进，危险可能来自连续，向下对角线或向上对角线，随着董事会的发展跟踪每一个。

(define (safe? r k dangers)
   (and (let loop ((rdangers (rdang dangers)))
           (cond ((null? rdangers) #t)
                 ((= r (car rdangers))
                  #f)
                 (else (loop (cdr rdangers)))))
        (let ((ddiag (- k r)))
           (let loop ((ddangers (ddang dangers)))
              (if (<= (car ddangers) ddiag)
                  (if (= (car ddangers) ddiag)
                      #f
                      #t)
                  (loop (cdr ddangers)))))
        (let ((udiag (+ k r)))
           (let loop ((udangers (udang dangers)))
              (if (>= (car udangers) udiag)
                  (if (= (car udangers) udiag)
                      #f
                      #t)
                  (loop (cdr udangers)))))))

格式变化的中等改进，只需要做一个比较来检查与之前的两个。不要认为保持对角线排序会让我付出任何代价，但我认为它也不会节省时间。

(define (update-dangers r k dangers)
  (list
     (cons r (rdang dangers))
     (insert (- k r) (ddang dangers) >)
     (insert (+ k r) (udang dangers) <))) 

 (define (insert x sL pred)
   (let loop ((L sL))
      (cond ((null? L) (list x))
            ((pred x (car L))
             (cons x L))
            (else (cons (car L)
                        (loop (cdr L)))))))

(define (rdang dangers)
  (car dangers))
(define (ddang dangers)
  (cadr dangers))
(define (udang dangers)
  (caddr dangers))
于 2015-12-10T10:57:04.730 回答