0

我只需要每行有 3 个产品。每个产品都在模板“OneProduct”（不包括在内）中，并且推杆大多数表标签都在此表之外。以下实际上确实有效，但是，它是如何以正确的方式完成的？

<xsl:if test="(position() mod 3) = 1">
  <xsl:text disable-output-escaping="yes">
     <![CDATA[<TR name="PROD_ROW">]]>
  </xsl:text>
</xsl:if>

  <TD width="33%" align="center" name="PRODUCT_CELL">

    <xsl:call-template name="OneProduct">
      <xsl:with-param name="productId" select="$productId" /> 
    </xsl:call-template>

  </TD>

<xsl:if test="( (position()+1) mod 3 = 1)">
   <xsl:text disable-output-escaping="yes">
      <![CDATA[</TR>]]>
   </xsl:text>
</xsl:if>
4

1 回答 1

1

在回答您的问题时，这不是首选方式。这是你可以用程序语言做的事情；迭代元素，增加一个计数器，然后在到达第 3 个、第 6 个等元素时输出定界元素。但是 XSLT 是一种函数式语言，需要一种不同的方法。

您可以做的是使用xsl:apply-templates来选择每行中的第一个元素。假设你有一些这样的 XML

<products>
   <product id="1" name="Product 1" />
   <product id="2" name="Product 2" />
   <product id="3" name="Product 3" />
   <product id="4" name="Product 4" />
   <product id="5" name="Product 5" />
</products>

那么你的xsl:apply-templates会是这样的：

<xsl:apply-templates select="product[position() mod 3 = 1]" />

在与产品元素匹配的模板中，您将选择行中的所有元素（即当前元素，加上以下两个元素）

<xsl:apply-templates 
     select="self::*|following-sibling::product[position() &lt; 3]" mode="cell" />

注意这里使用模式，因为您将有两个模板匹配产品，您需要区分它们。

最后，您只需使用这个“单元格”模板来输出产品。

<xsl:template match="product" mode="cell">
    <td>
       <xsl:value-of select="@name" />
    </td>
</xsl:template>

唯一需要担心的是，如果每行没有确切数量的单元格（例如，在此示例中，有五个产品，因此最后一行只有两个单元格。

尝试以下 XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="html" />

<xsl:template match="/*">
    <table>
       <xsl:apply-templates select="product[position() mod 3 = 1]" />
    </table>
</xsl:template>

<xsl:template match="product">
    <tr>
       <xsl:apply-templates select="self::*|following-sibling::product[position() &lt; 3]" mode="cell" />
    </tr>
</xsl:template>

<xsl:template match="product" mode="cell">
    <td>
        <xsl:if test="position() &lt; 3 and not(following-sibling::product[1])">
            <xsl:attribute name="colspan">
               <xsl:value-of select="4 - position()" />
            </xsl:attribute>
        </xsl:if>
       <xsl:value-of select="@name" />
    </td>
</xsl:template>
</xsl:stylesheet>

应用于示例 XML 时，输出以下内容

<table>
   <tr>
      <td>Product 1</td>
      <td>Product 2</td>
      <td>Product 3</td>
   </tr>
   <tr>
      <td>Product 4</td>
      <td colspan="2">Product 5</td>
   </tr>
</table>
于 2013-06-06T08:00:06.360 回答