0

我需要弄清楚当前日期 6/6/2013 是 MM/DD/YYYY 还是 DD/MM/YYYY 格式。因此它们都是“6”。

我要做的是获取当前日期，然后添加 3 天，从那里我会知道哪个是 MM 字段，因为它不会改变。我不知道如何批量打印日期+3天。甚至可能吗？有没有人有任何想法？我已经做了几个小时了。我尝试使用 GNU date 命令，但我必须指定输出，所以它没有帮助.. GRR！

请注意，这是针对 WINDOWS 的。请注意，我正在查看的文件无法更改，因此如果日期是 2013 年 9 月 9 日，那么我必须使用这些文件来确定字段。

编辑：我最终使用了以下代码：这有点过头了，但你可以看到我基本上是如何做到的。我设置该值的原因是因为我将它与 Gnu date.exe 命令结合使用，该命令非常擅长根据特定日期提供日期。所以我在脚本的其他地方这样使用它：date.exe --date "Now -90 days" %DATEFORMAT%。我不得不放弃另一篇文章中建议的日期 /T 选项，因为这实际上并不能显示所有情况下的正确数据。

for /F "skip=1 tokens=3" %%a in ('reg query "HKCU\Control Panel\International" /v sShortDate ^< NUL') do (
    echo.%%a|findstr /C:"/" >nul 2>&1 && set DELIM=/
    echo.%%a|findstr /C:"-" >nul 2>&1 && set DELIM=-
    echo.%%a|findstr /C:"." >nul 2>&1 && set DELIM=.

    for /F "tokens=1-3 delims=-/." %%b in ("%%a") do (
        set format=%%b%%c%%d
    )
)

if %DELIM%==/ ( 
    :: US English options 
    if %format%==Mdyyyy set DATEFORMAT=+%%-m/%%-d/%%Y 
    if %format%==Mdyy set DATEFORMAT=+%%-m/%%-d/%%y
    if %format%==MMddyy set DATEFORMAT=+%%m/%%d/%%y
    if %format%==MMddyyyy set DATEFORMAT=+%%m/%%d/%%Y
    if %format%==yyMMdd set DATEFORMAT=+%%y/%%m/%%d 

    :: UK English options
    if %format%==ddMMyyyy set DATEFORMAT=+%%d/%%m/%%Y
    if %format%==ddMMyy set DATEFORMAT=+%%d/%%m/%%y
    if %format%==dMyy set DATEFORMAT=+%%-d/%%-m/%%y

) else if %DELIM%==- (
    if %format%==yyyyMMdd set DATEFORMAT=+%%Y-%%m-%%d
    if %format%==ddMMMyy set DATEFORMAT=+%%d/%%m/%%y
    if %format%==dMyy set DATEFORMAT=+%%-d-%%-m-%%y
) else if %DELIM%==. (
    if %format%==dMyy set DATEFORMAT=+%%-d.%%-m.%%y
) else (
    echo ERROR: System was unable to identify dateformat.
    ping -n 10 -w 1 127.0.0.1 >NUL
)
4

5 回答 5

5

要批量获取当前日期格式，请尝试以下操作：

@echo off&setlocal
reg query "HKCU\Control Panel\International" /v sShortDate

..输出（可能会有所不同）：

 sShortDate  REG_SZ  M/d/yyyy
于 2013-06-06T06:07:21.633 回答
2

了解语言环境日期格式的一种简单方法是使用命令的输入格式，即变量date的相同输出格式。%date%例如，当我date在我的计算机上执行时，我得到了这个输出：

The current date is: 06/06/2013
Enter the new date: (dd-mm-yy)

所以诀窍是获取最后一部分(dd-mm-yy)并处理它：

for /F "skip=1 tokens=2 delims=()" %%a in ('date ^< NUL') do (
   for /F "tokens=1-3 delims=-/." %%b in ("%%a") do (
      for /F "tokens=1-3 delims=-/." %%x in ("%date%") do (
         set "%%b=%%x" & set "%%c=%%y" & set "%%d=%%z"
      )
   )
)
echo Day: %dd%, Month: %mm%, Year: %yy%

对于 "date+3 days" 部分，您可以将日期转换为Julian Day Number，添加 3 并将数字转换回日期，但有更简单的解决方案：

@echo off
setlocal EnableDelayedExpansion

for /F "skip=1 tokens=2 delims=()" %%a in ('date ^< NUL') do (
   for /F "tokens=1-3 delims=-/." %%b in ("%%a") do (
      for /F "tokens=1-3 delims=-/." %%x in ("%date%") do (
         set /A %%b=1%%x %% 100, %%c=1%%y %% 100, %%d=%%z
      )
   )
)
echo Today's date. Day: %dd%, Month: %mm%, Year: %yy%

set m=0
for %%a in (31 28 31 30 31 30 31 31 30 31 30 31) do (
   set /A m+=1
   set daysPerMonth[!m!]=%%a
)
set /A yyMOD4=yy %% 4
if %yyMOD4% equ 0 set daysPerMonth[2]=29

rem Add 3 days to today's date
set /A dd+=3
if %dd% gtr !daysPerMonth[%mm%]! (
   set /A dd-=daysPerMonth[%mm%], mm+=1
   if !mm! gtr 12 (
      set /A mm=1, yy+=1
   )
)
if %dd% lss 10 set dd=0%dd%
if %mm% lss 10 set mm=0%mm%

echo Today + 3 days date. Day: %dd%, Month: %mm%, Year: %yy%
于 2013-06-06T13:03:13.297 回答
2

对不起，我对这个话题有点困惑。

在您最初的问题中，您需要“确定当前日期是 MM/DD/YYYY 还是 DD/MM/YYYY 格式”，因为您要“取当前日期，然后添加 3 天”。在我的第一个答案中，我解决了之前要求的两个问题（我认为是正确的）。但是，您最终使用的代码似乎解决了一个完全不同的问题：将语言环境日期格式转换为某种特定的日期格式。如果这是新请求，那么这是我的新解决方案：

@echo off
setlocal EnableDelayedExpansion

rem Get the date format
for /F "skip=1 tokens=3" %%a in ('reg query "HKCU\Control Panel\International" /v 

sShortDate ^< NUL') do (
   set DATEFORMAT=%%a
)

rem Convert the special case: dd-MMM-yy to +%%d/%%m/%%y
if %DATEFORMAT% equ dd-MMM-yy (
   set DATEFORMAT=+%%d/%%m/%%y
) else (
   rem Convert the rest of cases
   for %%a in ("yyyy=%%Y" "yy=%%y" "MM=%%x" "M=%%-x" "x=m" "dd=%%x" "d=%%-x" "x=d") do (
      set DATEFORMAT=!DATEFORMAT:%%~a!
   )
)
set DATEFORMAT=+!DATEFORMAT!

ECHO %DATEFORMAT%

日期管理例程对我来说很重要，因此如果您可以测试此解决方案并报告它是否正确转换了您希望​​的日期格式，或者指出任何转换错误，我将不胜感激。非常感谢...

于 2013-06-16T08:00:30.077 回答
1

这是一种获取时间戳的区域不敏感方式 - Win XP Pro 及更高版本。

目前下面有 YYYYMMDD_HHMMSS 和 YYYY-MM-DD_HH-MM-SS。您可以更改项目的顺序以获得所需的时间戳。

:: timestamp YYYYMMDD_HHMMSS
@echo off
for /f "delims=" %%a in ('wmic OS Get localdatetime  ^| find "."') do set dt=%%a
set dt=%dt:~0,8%_%dt:~8,6%
echo %dt%
pause

一个带有可以重新排列的单个项目：

:: timestamp YYYY-MM-DD_HH-MM-SS
@echo off
for /f "delims=" %%a in ('wmic OS Get localdatetime  ^| find "."') do set dt=%%a
set dt=%dt:~0,4%-%dt:~4,2%-%dt:~6,2%_%dt:~8,2%-%dt:~10,2%-%dt:~12,2%
echo %dt%
pause
于 2013-06-06T10:13:33.670 回答
0

如果您使用的是 Windows，则可以逐步浏览文件C:\Windows\Temp夹中的文件，直到找到day大于 12 的文件。这是我编写的批处理文件，它演示了一种执行此操作的方法。您可以在另一个操作系统上采用类似的方法，尽管我不知道语法......

@echo off

setlocal

for /f "tokens=1,2,3,4* delims=/ " %%i in ('dir c:\windows\temp /4 ^| find "M   "') do (
  if %%i gtr 2000 (if %%j gtr 12 (set _format=YYYY/DD/MM) else (if %%k gtr 12 (set _format=YYYY/MM/DD)))
  if %%j gtr 2000 (if %%i gtr 12 (set _format=DD/YYYY/MM) else (if %%k gtr 12 (set _format=MM/YYYY/DD)))
  if %%k gtr 2000 (if %%i gtr 12 (set _format=DD/MM/YYYY) else (if %%j gtr 12 (set _format=MM/DD/YYYY)))
  if defined _format goto :TheEnd
)

:TheEnd
echo %_format%

endlocal
于 2013-06-06T05:10:45.280 回答