0

我有一个来自我的 Minecraft 服务器的 XML 结构化用户列表，我想在我的 QML 应用程序中显示它。如果提要中只有一 (1) 个用户名，它就可以工作，但如果有更多，我根本不会显示任何用户名。

XML 结构（我们称之为 xml.file）：

<server>
  <status>Online</status>
  <connected-users>
    <user>username1</user>
    <user>username2</user>
  </connected-users>
</server>

然后是 QML 代码（缩短）：

import QtQuick.XmlListModel 2.0
XmlListModel {
    id: msmData
    source: "xml.file"
    query: "/server"

    XmlRole { name: "serverState"; query: "status/string()" }
    XmlRole { name: "connectedUser"; query: "connected-users/user/string()" }
}
ListView {
                    id: userList
                    width: parent.width
                    height: units.gu(5)
                    model: msmData
                    delegate: ListItem.Standard {
                        text: connectedUser
                        onClicked: {
                            console.debug('Debug: User clicked "'+connectedUser+'"')
                            checkCurrentUser(connectedUser)
                            PopupUtils.open(userDialog, userList)
                        }
                    }
4

1 回答 1

0

如果您将 connectedUser 的查询更改为connected-users/user[1]/string()，您会注意到您可以再次访问 username1（还要注意 Xpath 从 1 而不是 0 开始索引）。这个错误（虽然最初是为 Qt 4.7 报告的）表明对访问嵌套列表的支持相当缺乏。

我在尝试访问 RSS 提要中文章的多个类别时遇到了同样的问题，并通过启动一个来解决它，XMLHttpRequest通过 JavaScript 解析我的所有数据（包括嵌套列表，无论是博客文章的标签还是服务器上连接的用户），然后附加到ListModel附加到 ListView的 QML 。可能有一种方法可以遍历 XmlListModel 中的嵌套列表——正如错误的评论之一所暗示的那样——但我还没有尝试过该评论中链接的方法。

这是一个使用 XMLHttpRequest 和您在名为“test.xml”的文件中提供的 XML的工作示例（改编自此处的讨论帖）：

import QtQuick 2.0
import Ubuntu.Components 0.1
import Ubuntu.Components.ListItems 0.1 as ListItem

Rectangle {
    width: 360
    height: 360
    ListModel {
        id: msmData
    }
    Component.onCompleted: {
        var request = new XMLHttpRequest();
        request.onreadystatechange = function() {
            if (request.readyState === XMLHttpRequest.DONE) {
                var document = request.responseXML.documentElement;
                var msmServer = {
                    status: '',
                    users: []
                };
                for(var i = 0; i < document.childNodes.length; i++) {
                    var record = document.childNodes[i];
                    if (record.tagName === 'status') {
                        msmServer.status = record.childNodes[0].nodeValue;
                    } else if (record.tagName === 'connected-users') {
                        for (var k = 0; k < record.childNodes.length; k++){
                            var elem = record.childNodes[k];
                            if(elem.tagName === 'user'){
                                msmServer.users.push({ name: elem.childNodes[0].nodeValue });
                            }
                        }
                    }
                }
                msmData.append(msmServer);
            }
        }
        request.open('GET', 'test.xml');
        request.send();
    }
    ListView {
        id: userList
        width: parent.width
        height: units.gu(5)
        model: msmData
        delegate: ListItem.Subtitled {
            text: status
            subText: {
                var userText = '';
                for (var i = 0; i < users.count; i++) {
                    if (i > 0) userText += ', ';
                    userText += users.get(i).name;
                }
                return userText;
            }
            onClicked: {
                console.debug('Debug: User clicked "'+status+'"')
                for (var i = 0; i < users.count; i++) {
                    console.debug(users.get(i).name);
                }
            }
        }
    }
}
于 2013-06-01T15:14:04.240 回答