5

我在这里逐字遵循 MSDN 文档，但无济于事。

我的 XML 示例：

<Ticket xmlns:i="http://www.w3.org/2001/XMLSchema-instance">
    <LogNo>454564</LogNo>
    <CaseNumber>
        <Part1>FGV</Part1>
        <Part2>9999</Part2>
        <Part3>88888888       </Part3>
    </CaseNumber>
</Ticket>

我的 XSLT 示例：

<?xml version="1.0" encoding="ISO-8859-1"?>
 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

 <xsl:strip-space elements="*" />

<xsl:template match="/text">
  <xsl:value-of select='normalize-space()'/>
</xsl:template>

 <xsl:template match="Ticket">
  <Ticket><xsl:attribute name="LogNumber"><xsl:value-of select="LogNo"/></xsl:attribute>
    <CaseNumber><xsl:value-of select="CaseNumber/Part1"/>-<xsl:value-of select="CaseNumber/Part2"/>-<xsl:value-of select="CaseNumber/Part3"/></CaseNumber>
  </Ticket>
 </xsl:template>

 </xsl:stylesheet>

我的输出 XML：

<?xml version="1.0" encoding="IBM437"?>
<Tickets>
  <Ticket LogNumber="454564">
    <CaseNumber>FGV-9999-88888888       </CaseNumber>
  </Ticket>
</Tickets>

我在用

<xsl:template match="/text">
    <xsl:value-of select='normalize-space()'/>
</xsl:template>

正如 MSDN 文章和网上其他所有人所说，但似乎无法从 CaseNumber Part3 中删除尾随空格。有什么我做错了吗？

4

4 回答 4

7

一种方法是normalize-space直接在<xsl:value-of>：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes" />

  <xsl:template match="node() | @*">
    <xsl:copy>
      <xsl:apply-templates select="node() | @*" />
    </xsl:copy>
  </xsl:template>

  <xsl:template match="Ticket">
    <Ticket LogNumber="{LogNo}">
      <xsl:apply-templates select="CaseNumber" />
    </Ticket>
  </xsl:template>

  <xsl:template match="CaseNumber">
    <xsl:copy>
      <xsl:value-of select="concat(
        normalize-space(Part1), '-',
        normalize-space(Part2), '-',
        normalize-space(Part3)
      )" />
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>
于 2013-05-31T07:04:44.013 回答
6

更改<xsl:template match="/text">
为：xsl:template match="text()">

并使用xsl:apply-templates而不是xsl:value-of.
因此尝试：

<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:strip-space elements="*" />

    <xsl:template match="text()">
        <xsl:value-of select='normalize-space()'/>
    </xsl:template>

    <xsl:template match="Ticket">
        <Ticket>
            <xsl:attribute name="LogNumber">
                <xsl:value-of select="LogNo"/>
            </xsl:attribute>
            <CaseNumber>
                <xsl:apply-templates select="CaseNumber/Part1"/>-<xsl:apply-templates select="CaseNumber/Part2"/>-<xsl:apply-templates select="CaseNumber/Part3"/>
            </CaseNumber>
        </Ticket>
    </xsl:template>

</xsl:stylesheet>

这将生成以下输出：

<Ticket LogNumber="454564"><CaseNumber>FGV-9999-88888888</CaseNumber></Ticket>
于 2013-05-31T07:09:56.213 回答
0

为了规范化 XML-doc Y 的副本，可以实现下一个模板：

 <?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0"
        xmlns:ns1="http://logiasoftware.fi/2010/CanonicalDataModel"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" indent="yes"/>
    <xsl:template name="NormalizeSpace">
        <xsl:element name="{name()}">
            <xsl:choose>
                <xsl:when test="*">
                    <xsl:for-each select="*">
                        <xsl:call-template name="NormalizeSpace"/>
                    </xsl:for-each>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="normalize-space()"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:element>
    </xsl:template>

    <xsl:template match="/">
        <xsl:for-each select="*">
            <xsl:call-template name="NormalizeSpace"/>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>
于 2016-09-27T09:05:42.117 回答
0

我认为 normalize-space 不起作用，因为我仍然在长字符串中出现换行符。原来我的问题出在我的 xsl:output 配置上。我的配置是：

<xsl:output encoding="UTF-8" method="html" omit-xml-declaration="yes"/>

我需要更改输出方法：

<xsl:output encoding="UTF-8" method="text" omit-xml-declaration="yes"/>
于 2017-11-21T15:01:47.763 回答