2

我想在 XSL 中获取迭代次数，但在我的 foreach 中我有一个条件，我想编写我的迭代，但仅在我的条件下为真。

我使用“位置（）”，我想在表格中写位置。

<xsl:for-each ... >
  <xsl:if test="Jordan = $name">
    <xsl:value-of select="position() = 1">
  </xsl:if>
</xsl:for-each>

在我得到这个 1-3 之后，我想要 1-2（只有成功条件）

我的 XML ：

<root>
  <user>
    <name>Jordan</name>
    <forename>Michael</forename>
  </user>
  <user>
    <name>Braun</name>
    <forename>Steve</forename>
  </user>
  <user>
    <name>Jordan</name>
    <forename>David</forename>
  </user>
</root>

预期输出一个 HTML 表格

<table>
  <tr>
    <td>1</td>
    <td>Michael</td>
  </tr>
  <tr>
    <td>2</td>
    <td>David</td>
  </tr>
</table>
4

2 回答 2

0

编辑： OP 改变了他们的问题以提供新信息。这需要一个不同于原始答案的答案。

如果目标是只为那些子<user>元素<name>为“Jordan”的元素输出信息，那么这个 XSLT 应该可以解决问题：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="/*">
    <table>
      <xsl:apply-templates select="*[name = 'Jordan']/forename"/>
    </table>
  </xsl:template>

  <xsl:template match="forename">
    <tr>
      <td>
        <xsl:value-of select="position()"/>
      </td>
      <td>
        <xsl:apply-templates/>
      </td>
    </tr>
  </xsl:template>

</xsl:stylesheet>

编辑：这个答案留给后代。

与其将其视为“递增循环问题”（这更像是一种过程方法），不如将其视为一个分组问题——至少，它与 XSLT 相关。在 XSLT 1.0 中这样做意味着使用Muenchian Grouping。

当这个 XSLT：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:key name="kForenames" match="forename" use="."/>

  <xsl:template match="/*">
    <table>
      <xsl:apply-templates
        select="*/forename[generate-id() =
                           generate-id(key('kForenames', .)[1])]"/>
    </table>
  </xsl:template>

  <xsl:template match="forename">
    <tr>
      <td>
        <xsl:value-of select="position()"/>
      </td>
      <td>
        <xsl:apply-templates/>
      </td>
    </tr>
  </xsl:template>

</xsl:stylesheet>

...针对提供的 XML 应用：

<root>
  <user>
    <name>Jordan</name>
    <forename>Michael</forename>
  </user>
  <user>
    <name>Braun</name>
    <forename>David</forename>
  </user>
  <user>
    <name>Jordan</name>
    <forename>David</forename>
  </user>
</root>

...产生了想要的结果：

<table>
  <tr>
    <td>1</td>
    <td>Michael</td>
  </tr>
  <tr>
    <td>2</td>
    <td>David</td>
  </tr>
</table>
于 2013-05-29T17:15:15.750 回答
0 
<xsl:variable name="mergedData">
     <xsl:for-each ... >
          <xsl:if test="Jordan = $name">
               <xsl:copy-of select="."/>
          </xsl:if>
     </xsl:for-each>
</xsl:variable>

<xsl:for-each select="msxsl:node-set($mergedData)/*">
    <xsl:value-of select="position()"/>
</xsl:for-each>
于 2016-06-27T10:24:33.083 回答