3

我使用 Tcl 自动化网络切换，并期望在我的 Fedora 12 上使用脚本。测试日志和带有附件的结果被发送到电子邮件收件箱 (office 365) - 浏览器和 Outlook 模式。

我想知道是否有办法使用 TCL 或 shell 脚本使彩色字体出现在我的电子邮件中。

例如，在发送到电子邮件的报告中，文本“通过”应以绿色粗体显示，“失败”字体必须以红色粗体显示。tput 有用吗？请帮忙。提前致谢。

4

3 回答 3

3

只需使用 html 电子邮件（带content-type: text/html标题）和内联 css 对其进行着色。

Passed应该

<span style="color:green"><font color="green"></font></span>

如果跨度不起作用，此处span提供样式提供后备。
font一些电子邮件客户端可能会剥离这些内联样式。

于 2013-05-29T07:03:07.897 回答
3

您要求两种不同的东西：电子邮件中的彩色文本和外壳中的彩色文本。其他人已经回答了电子邮件部分，所以我想解决外壳部分。对于终端输出，我使用term::ansi::send包。这是一个示例：

package require cmdline
package require term::ansi::send

proc color_puts {args} {
    # Parse the command line args
    set options {
        {bg.arg default "The background color"}
        {fg.arg default "The foreground color"}
        {nonewline "" "no ending new line"}
        {channel.arg stdout "Which channel to write to"}
    }
    array set opt [cmdline::getoptions args $options]

    # Set the foreground/background colors
    ::term::ansi::send::sda_fg$opt(fg)
    ::term::ansi::send::sda_bg$opt(bg)

    # puts
    if {$opt(nonewline)} {
        puts -nonewline $opt(channel) [lindex $args end]
    } else {
        puts $opt(channel) [lindex $args end]
    }

    # Reset the foreground/background colors to default
    ::term::ansi::send::sda_fgdefault
    ::term::ansi::send::sda_bgdefault
}

#
# Test
#

puts "\n"
color_puts -nonewline -fg magenta "TEST"
color_puts -nonewline -fg blue    " RESULTS"
puts "\n"

color_puts -fg green "test_001 Up/down direction movements passed"
color_puts -fg red "test_002 Left/right direction movements failed"

讨论

  • 适用的标志color_puts用于-bg背景颜色、-fg前景色、-nonewline抑制换行符输出以及-channel将输出定向到文件。
  • 可用颜色为黑色、蓝色、红色、绿色、黄色、洋红色、青色、白色和默认值。有关更多信息，请查看term::ansi::send包装。
于 2013-05-29T14:10:27.630 回答
2

因此，这是我用来发送邮件的简单脚本（您可能需要提供用户名/密码smtp::sendmessage）

set textpart [::mime::initialize -canonical text/plain -string {Hello World}]
set htmlpart [::mime::initialize -canonical text/html -string  {<font color="green">Hello World</font>}]
set tok [::mime::initialize -canonical multipart/alternative -parts [list $textpart $htmlpart] -header {From test@example.com}]
::mime::setheader $tok Subject {Hello World}
::smtp::sendmessage $tok -servers smtp.example.com -recipients recipient@example.com -originator test@example.com
::mime::finalize $tok -subordinates all

一些注意事项：

  • 您可以对 html 和纯文本使用不同的消息，但您应该在两者中都包含所有信息。客户端通常会选择它可以显示的更好的格式。
  • 如果要发送附件，则必须添加另一个multipart/mixed，（像构建它一样multipart/alternative），它的第一部分应该是消息（您的multipart/alternative），其他部分是附件。
  • 根据一些或多或少模糊的情况， smtp 和 mime 包使用一些无效的系统默认值（例如您的用户名带有空格）。如果发生这种情况，您必须为一个或多个此命令提供额外信息。
于 2013-05-29T12:32:18.820 回答