0

我有一个用户希望在她登录到我们的终端服务器时将她的本地桌面打印机作为默认打印机。我为此创建了一个简单的登录脚本

Set WSHNetwork = CreateObject("WScript.Network")
WSHNetwork.SetDefaultPrinter "HP LaserJet 6P (redirected 3)"

问题在于，无论出于何种原因，打印机名称都会不断更改最后一位数字。HP LaserJet 6P（重定向）、HP LaserJet 6P（重定向 2）和HP LaserJet 6P（重定向 1）都是打印机显示方式的示例。

我不太了解 VBScript，无法解释这些更改，希望有人能帮助我找到正在使用的名称变体，并将其设置为默认打印机。

我找到了一个可能有帮助的片段，但我不确定如何正确实现它。

Function printerExists(str)
    printerExists = False
    Dim objWMIService
    Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")

    Dim colPrinters
    Set colPrinters = objWMIService.ExecQuery("Select * From Win32_Printer")

    Dim objPrinter
    For Each objPrinter In colPrinters
        If objPrinter.Name = str Then
            printerExists = True
            Exit For
        End If
    Next
End Function
4

3 回答 3

0

打印机的名称是动态的，因为它通过终端服务器或远程桌面连接从本地工作站的打印机列表进行重定向。如果其他人的打印机与上述代码中被测试的打印机型号相同，则可能会错误地将其他人的打印机设置为此人的默认值。

RDP 连接或终端服务器总是会尝试将您的本地默认打印机设置为重定向的默认打印机，因此要将“HP Laserjet 6P（重定向）”设置为您的默认设置，您必须将本地工作站上的“HP Laserjet 6P”设置为您的连接到服务器之前的默认设置。

于 2013-08-07T03:08:01.450 回答
0

您可以更改该代码以查找包含名称第一部分的任何内容，"HP LaserJet 6P (redirected"：

Dim WSHNetwork
Dim objWMIService
Dim colPrinters
Dim objPrinter

Set WSHNetwork = CreateObject("WScript.Network")
Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
Set colPrinters = objWMIService.ExecQuery("Select * From Win32_Printer")

For Each objPrinter In colPrinters
    If InStr(objPrinter.Name, "HP LaserJet 6P (redirected") Then
        WSHNetwork.SetDefaultPrinter objPrinter.Name
        Exit For
    End If
Next

Set WSHNetwork = nothing
Set objWMIService = nothing
Set colPrinters = nothing
于 2013-05-31T17:39:21.557 回答
0

如果您无法修复更改名称的问题，您应该能够解决它。

从循环构造开始。在这种情况下，我们将使用 for 循环：

For i = 0 To 5
    'things happen
next

我选择将数字限制为 5 或更低，但可以根据您的需要进行更改。然后我们需要一个方法来包含打印机名称的所有可能性。如果所有 te 名称都包含一个不带任何特殊代码的数字，但这里我们将使用 if 语句表示如果该数字为 0，则不包含该数字。

If i = 0 Then
    testPrinter = "HP LaserJet 6P (redirected)"
Else
    testPrinter = "HP LaserJet 6P (redirected " & i & ")"
End If

然后，我们将利用您提供的 printerExists 函数来确定打印机是否存在，如果存在则设置默认打印机。

If printerExists(testprinter) = True Then
    WSHNetwork.SetDefaultPrinter testPrinter
    WScript.Quit
End If

为了完成脚本，我们将所有部分放在一起并添加printerExists 函数。最终的脚本最终看起来像这样：

Set WSHNetwork = CreateObject("WScript.Network")

i = 1 : testPrinter = "HP LaserJet 6P (redirected)"

For i = 0 To 5
    If i = 0 Then
        testPrinter = "HP LaserJet 6P (redirected)"
    Else
        testPrinter = "HP LaserJet 6P (redirected " & i & ")"
    End If

    If printerExists(testprinter) = True Then
        WSHNetwork.SetDefaultPrinter testPrinter
        WScript.Quit
    End If
next

Function printerExists(str)
    printerExists = False
    Dim objWMIService
    Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")

    Dim colPrinters
    Set colPrinters = objWMIService.ExecQuery("Select * From Win32_Printer")

    Dim objPrinter
    For Each objPrinter In colPrinters
        If objPrinter.Name = str Then
            printerExists = True
            Exit For
        End If
    Next
End Function

请记住字符串比较，例如函数中使用的比较：

If objPrinter.Name = str Then

区分大小写。

于 2013-05-31T17:26:57.480 回答