delphi - 如何在 Inno 中制作 Delphi 安装程序

Question

我是 Delphi 的新手，想知道您需要在 Inno Setup Compiler 中添加什么代码才能为 Delphi 程序制作安装程序？我正在使用 Delphi 7 和 Inno Setup Compiler 5.5.3。感谢您的帮助。

Answer 1

这取决于您的需求。INNOSetup 使用 Pascal 作为脚本引擎，因此如果您来自 Delphi/Pascal 世界，学习曲线很容易。它也有很好的文档，您可以通过在光标位于其上时按 F1 或谷歌搜索来获取有关几乎任何关键字的更多信息。

这是我用作为任何项目创建安装程序的启动器的基本脚本：

#define ApplicationName "FileSyncer"
#define ApplicationExe "filesyncer.exe"

[Setup]
AppName={#ApplicationName}
AppVerName={#ApplicationName}
DefaultDirName={pf}\{#ApplicationName}
DefaultGroupName={#ApplicationName}
UninstallFilesDir={app}\uninstall
UninstallDisplayName={#ApplicationName}
Compression=lzma2
SolidCompression=yes
OutputDir=.\
OutputBaseFilename=setup
UninstallDisplayIcon={app}\{#ApplicationExe}
DisableProgramGroupPage=yes
AppMutex=FileSyncerClientInstanceMutex
WizardImageFile=setup_images\big.bmp
WizardSmallImageFile=setup_images\small.bmp
ArchitecturesInstallIn64BitMode=x64

[Files]
Source: "pfiles_x86\*.*"; DestDir: "{app}"; Check: not Is64BitInstallMode
Source: "pfiles_x64\*.*"; DestDir: "{app}"; Check: Is64BitInstallMode

[Icons]
Name: "{group}\{#ApplicationName}"; Filename: "{app}\{#ApplicationExe}"; WorkingDir: "{app}"
Name: "{group}\Uninstall"; Filename: "{uninstallexe}"

[Run]
Filename: "{app}\{#ApplicationExe}"; Description: "Launch FileSyncer"; Flags: postinstall nowait skipifsilent runascurrentuser

有关更多示例，我建议您查看Inno Setup 5\Inno Setup Example Scripts目录，那里有很多示例。此外，谷歌搜索“ innosetup 示例脚本”之类的内容将返回有用的结果。