3

使用 VHDL 2008 是否有一种方法可以定义一个具有通用类型的抽象实体，该通用类型具有该类型的端口以及从该基本类型派生的不受约束的数组或记录？像这样的东西：

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;

entity COMP_EXCH is
  generic(type T;                             -- VHDL-2008 abstract generic base type
          function "<"(L,R:T) return BOOLEAN; -- VHDL-2008 abstract generic function
          LATENCY:INTEGER:=0);
  port(I0,I1:in T;
       O:out T_VECTOR(0 to 1));
end COMP_EXCH;

architecture TEST of COMP_EXCH is
begin
  O<=(I1,I0) when I1<I0 else (I0,I1);
end TEST;

其中 T_VECTOR 是：

T_VECTOR 类型是 T 的数组（整数范围 <>）；

T 是任意抽象基类型。挑战在于如何插入 T_VECTOR 的定义，该定义取决于 T 在引入 T 的泛型之后但在需要 T_VECTOR 的端口之前？两种类型如何保持通用和抽象，但其中一种是另一种的不受约束的数组？如果没有抽象类型，人们将使用一个包来实现这一点，其中将包含 T 和 T_VECTOR 的类型定义，但是如何在 VHDL 2008 中使用抽象类型来完成呢？

我希望能够有许多派生类型，如无约束数组或记录（例如，具有 T 类型的实部和虚部的复杂记录）仍然是抽象的，并使用它们来定义抽象组件，如上面的示例。

4

3 回答 3

1

我现在正在回答我自己的问题，这里是这个问题的一个部分解决方案：

library IEEE;
use IEEE.STD_LOGIC_1164.all;

package SORTER_PKG is
  subtype T is INTEGER; -- define T here to make package "generic"
  function "<"(L,R:T) return BOOLEAN;
  type T_VECTOR is array(INTEGER range <>) of T;
end SORTER_PKG;

package body SORTER_PKG is
  function "<"(L,R:T) return BOOLEAN is
  begin
    return L<R; -- overload "<" here for whatever T is
  end;
end SORTER_PKG;

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;

use work.SORTER_PKG.all;

entity COMP_EXCH is
  port(I0,I1:in T;
       O:out T_VECTOR(0 to 1));
end COMP_EXCH;

architecture TEST of COMP_EXCH is
  signal I:T_VECTOR(O'range);
begin
  I<=(I1,I0) when I1<I0 else (I0,I1);
end TEST;

解决方案是“通用的”，因为您可以在 SORTER_PKG 中的一个位置重新定义 T 和“<”，以使 COMP_EXCH 和排序网络设计的其余部分对任何内容进行排序，而无需对该代码进行任何更改。尽管它们不是真正的抽象类型，但 T 和 T_VECTOR 的行为类似于 COMP_EXCH 中的类型。唯一的缺点是，如果您在同一设计中需要具有不同基本类型 T 的多种分类器，那么您就不走运了——“穷人的”抽象网络分类器解决方案，它可以工作，但您只能使用一次。

这是解决初始问题的解决方法，但不是真正的解决方案。我仍然不知道是否可以在 VHDL 2008 中定义从类型泛型基本类型 T 派生的记录或数组，并在端口或信号声明中使用它而没有 T 的实际值。如果您尝试使 SORTER_PKG 成为具有泛型类型 T 的抽象泛型包，那么您不能在 COMP_EXCH 中使用该包，因为 T 没有实际值。VHDL 2008 非常接近真正的 OOP 硬件设计，但还没有实现。

于 2013-05-28T20:09:37.883 回答
0

我认为如果不创建一个包含 T 和 T_VECTOR 的中间包，你就无法到达你需要的地方——那么你可以为实体实例化那个包吗？

或者（这可能不符合你的最终目标）......这能行吗？

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;

entity COMP_EXCH is
  generic(type T;                             -- VHDL-2008 abstract generic base type
          function "<"(L,R:T) return BOOLEAN; -- VHDL-2008 abstract generic function
          LATENCY:INTEGER:=0);
  port(I0,I1:in T;
       O0,O1:out T);
end COMP_EXCH;

architecture TEST of COMP_EXCH is
begin
  O0<=I1 when I1<I0 else I0;
  O1<=I0 when I1<I0 else I1;
end TEST;
于 2013-05-28T15:38:16.000 回答
0

我刚刚遇到了一个类似的问题，我想将一个通用数据类型和一个相同数据类型的数组发送到一个实体。我的解决方案是通用的，但有点笨拙。我将 T 和 T_VECTOR 都发送给了实体。有问题的部分是实体内部似乎不理解 T_VECTOR 是一个数组，因此对于需要执行一些数组操作的每个函数（例如从数组中获取一个元素，我还必须发送单独的函数。我认为这最好用一个实际的例子来证明，所以这里是RTL 代码和testbench我认为这也应该适用于你的问题

于 2015-11-24T14:14:58.363 回答