2

Access 2010：我有一个包含 3 个布尔字段的表 - 称它们为 Field_A、Field_B 和 Field_C。

在数据输入表单上，用户应该能够检查（使值 TRUE）这些选项中的任何一个，但任何时候只有一个选项可以是 TRUE。如果 Field_B 已经为真并且用户想要更改它，因此 Field_C 是选择为 TRUE 的选项，他首先必须取消选择 Field_B（将其重置为 FALSE），然后才能选中表单上的 Field_C 框。

因此，我需要为这些字段中的每一个字段设置一些验证代码，如果用户尝试将一个字段设置为 TRUE，则会检查其他两个字段的状态。如果其他两个字段当前都为 FALSE，则允许将当前字段更改为 TRUE。但是，如果其他字段中的任何一个当前为 TRUE，它应该创建一个弹出消息，说明已经有另一个选择，并且必须首先将另一个字段更改为 FALSE，然后才能继续。

我尝试使用 Yes/No 选项的数值，设置条件验证，要求其他两个值的总和为零，然后才允许将感兴趣的字段（例如 Field_A）更改为 TRUE（值 = -1 ) （就像([Field_B] + [Field_C]) =0，但我不断收到语法错误。我对此很陌生，我不知道这是否真的只是一个简单的语法问题，或者是否需要完全不同的方法。

最后一条信息——将所有 3 个字段都设置为 FALSE 是可以接受的，所以我不希望在另一个字段从 TRUE 更改回 FALSE 时强制其中一个字段变为 TRUE。

4

2 回答 2

0

对于这 3 个复选框，您有两种可接受的组合：

  1. 都是False（未选中）
  2. 只有一个可以True（选中）

这意味着这些复选框值的总和必须为 0 或 -1。

? False + False + False
 0 
? False + False + True
-1

您可以在表单的代码模块中添加一个函数...

Private Function checkBoxProblem() As Boolean
    Dim blnReturn As Boolean
    Dim intSum As Integer
    Dim strPrompt As String

    intSum = Nz(Me.Field_A, 0) + Nz(Me.Field_B, 0) + Nz(Me.Field_C, 0)
    If Not (intSum = 0 Or intSum = -1) Then
        strPrompt = "only one box can be checked"
        MsgBox strPrompt
        blnReturn = True
    Else
        blnReturn = False
    End If
    checkBoxProblem = blnReturn
End Function

然后从这 3 个复选框中的每一个的更新前事件中调用该函数。

Private Sub Field_A_BeforeUpdate(Cancel As Integer)
    Cancel = checkBoxProblem
End Sub
Private Sub Field_B_BeforeUpdate(Cancel As Integer)
    Cancel = checkBoxProblem
End Sub
Private Sub Field_C_BeforeUpdate(Cancel As Integer)
    Cancel = checkBoxProblem
End Sub
于 2013-05-28T14:33:37.927 回答
0

数据输入表单后面的一些代码应该可以解决问题。尝试以下方式：

Option Compare Database
Option Explicit

Private Sub Field_A_BeforeUpdate(Cancel As Integer)
    Const ThisField = "Field_A"
    If Me.Field_A.Value Then
        If Me.Field_B.Value Then
            ShowMyMessage "Field_B", ThisField
            Cancel = True
        ElseIf Me.Field_C.Value Then
            ShowMyMessage "Field_C", ThisField
            Cancel = True
        End If
    End If
End Sub

Private Sub Field_B_BeforeUpdate(Cancel As Integer)
    Const ThisField = "Field_B"
    If Me.Field_B.Value Then
        If Me.Field_A.Value Then
            ShowMyMessage "Field_A", ThisField
            Cancel = True
        ElseIf Me.Field_C.Value Then
            ShowMyMessage "Field_C", ThisField
            Cancel = True
        End If
    End If
End Sub

Private Sub Field_C_BeforeUpdate(Cancel As Integer)
    Const ThisField = "Field_C"
    If Me.Field_C.Value Then
        If Me.Field_B.Value Then
            ShowMyMessage "Field_B", ThisField
            Cancel = True
        ElseIf Me.Field_A.Value Then
            ShowMyMessage "Field_A", ThisField
            Cancel = True
        End If
    End If
End Sub

Private Sub ShowMyMessage(OtherField As String, CurrentField As String)
    MsgBox _
            "You must un-select """ & OtherField & """" & _
                " before you can select """ & CurrentField & """", _
            vbExclamation, _
            "Mutually exclusive options conflict"
End Sub
于 2013-05-28T08:32:26.507 回答