vb.net - 在 for each 循环中删除一个对象

Question

我正在制作一款生存游戏，并试图在物体离开屏幕时将其移除。这是代码：

Public Sub tmrEnemyMove_Tick(sender As Object, e As EventArgs) Handles tmrEnemyMove.Tick
    Dim koopaAnimation As Boolean

    For Each enemy As enemy In lstEnemy
        enemy.enemy.Left = enemy.enemy.Left - 20

        If enemy.enemy.Tag = "koopa" Then
            enemy.enemy.Image = Image.FromFile(Application.StartupPath + "\Graphics\koopa" + Trim(Str(koopaPosition)) + ".png")
            If koopaAnimation = False Then
                If koopaPosition = 0 Then
                    koopaPosition = 1
                Else
                    koopaPosition = 0
                End If
            End If
            koopaAnimation = True
        End If

        If picMario.Left < enemy.enemy.Left AndAlso enemy.enemy.Left < picMario.Right Or picMario.Left < enemy.enemy.Right AndAlso enemy.enemy.Right < picMario.Right Then
            If picMario.Top < enemy.enemy.Top AndAlso enemy.enemy.Top < picMario.Bottom Or picMario.Top < enemy.enemy.Bottom AndAlso enemy.enemy.Bottom < picMario.Bottom Then
                'MsgBox("Collision")
            End If
        End If

        If enemy.enemy.Left < 0 Then
            lstEnemy.Remove(enemy)
            Me.Controls.Remove(enemy.enemy)
        End If
    Next
End Sub

我得到的错误是：mscorlib.dll 中发生了“System.InvalidOperationException”类型的未处理异常附加信息：集合已修改；枚举操作可能无法执行。

如果有人可以提供帮助，那就太好了，谢谢。

Answer 1

您不能在枚举期间从集合中删除对象。您根本无法修改集合。这将导致错误（Collection 已修改；枚举操作可能无法执行）。但是您可以将要删除/移除的对象添加到另一个集合中：

Dim removeEnemies = New List(Of enemy)
For Each enemy As enemy In lstEnemy
    ' ... '
    If enemy.enemy.Left < 0 Then
        removeEnemies.Add(enemy.enemy)
    End If
Next

For Each enemy In removeEnemies
    lstEnemy.Remove(enemy)
    Me.Controls.Remove(enemy.enemy)
Next

以下所有方法都会导致列表更改其版本（在枚举期间检查）：

• 添加
• 清除
• 插入
• 插入范围
• 消除
• 删除范围
• 删除时间
• 撤销
• [索引器设置器]
• 种类

另一种选择是使用 aFor-Loop并向后循环：

 For i As Int32 = lstEnemy.Count - 1 To 0 Step -1
    Dim enemy = lstEnemy(i)
    ' ... '
    If enemy.enemy.Left < 0 Then
        lstEnemy.Remove(enemy)
        Me.Controls.Remove(enemy.enemy)
    End If
Next

这不会引发该错误，但它不那么可读。您需要从list.Count - 1To开始，0因为您想要删除会更改Count属性的项目，并且在删除项目之前可用的索引现在导致ArgumentOutOfRangeException.

最后但并非最不重要的一点是，您可以使用 List.RemoveAll：

lstEnemy.RemoveAll(Function(enemy) enemy.enemy.Left < 0)

Answer 2

.NET 真的不喜欢在枚举其内容的过程中更改集合。如果您打算像这样从集合中删除元素，您可以尝试将foreach循环更改为循环。for

Answer 3

使用实体框架 (ElementAt(i)) 的一个示例：

for (int i = 0; i < db.Itens.Count(); i++)
{
    Item item = db.Itens.ElementAt(i);
    if (item.Id == 0) // put a condition
    {
        db.Itens.Remove(item);
        i--;
    }
}