5

我正在尝试创建一个程序来在屏幕上写入参数。我创建了一些程序来获取 C 函数参数，或者我使用 C 将参数发送到我的 asm 程序。有没有办法只使用汇编程序来获取程序参数

前任：

./Program "text"

我使用的是（Gnu 汇编程序）

通常我使用这些参数

[esp+4]

因为 esp 是程序/函数调用指针，但在纯 asm 中它没有获取命令行参数。

有没有办法做到这一点？

我用谷歌搜索了它，但我找不到太多信息

4

1 回答 1

18

在 Linux 上，来自 C 的熟悉变量argc和argv变量总是由内核在堆栈上传递，甚至可用于完全独立且不与 C 库中的启动代码链接的汇编程序。这记录在i386 System V ABI中，以及进程启动环境的其他详细信息（寄存器值、堆栈对齐）。

_start在x86 Linux 可执行文件的 ELF 入口点 (aka )：

  1. ESP指向argc
  2. ESP + 4指向argv[0]数组的开头。即您应该按原样传递给 main 的值char **argv，lea eax, [esp+4]而不是mov eax, [esp+4]）

最小汇编程序如何获得 argc 和 argv

我将展示如何阅读argv和argc[0]在 GDB 中。

命令行-x86.S

#include <sys/syscall.h>

    .global _start
_start:
    /* Cause a breakpoint trap */
    int $0x03

    /* exit_group(0) */
    mov $SYS_exit_group, %eax
    mov $0, %ebx
    int $0x80

cmdline-x86.gdb

set confirm off
file cmdline-x86
run
# We'll regain control here after the breakpoint trap
printf "argc: %d\n", *(int*)$esp
printf "argv[0]: %s\n",  ((char**)($esp + 4))[0]
quit

示例会话

$ cc -nostdlib -g3 -m32 cmdline-x86.S -o cmdline-x86
$ gdb -q -x cmdline-x86.gdb cmdline-x86
<...>  
Program received signal SIGTRAP, Trace/breakpoint trap.
_start () at cmdline-x86.S:8
8   mov $SYS_exit_group, %eax
argc: 1
argv[0]: /home/scottt/Dropbox/stackoverflow/cmdline-x86

解释

  • 我放置了一个软件断点 ( int $0x03) 以使程序在 ELF 入口点 ( ) 之后立即陷入调试器_start。
  • 然后我printf在 GDB 脚本中使用了打印
    1. argc用表达式*(int*)$esp
    2. argv用表达式((char**)($esp + 4))[0]

x86-64版本

差异很小：

  • 用RSP替换ESP
  • 将地址大小从 4 更改为 8
  • exit_group(0)当我们调用以正确终止进程时，符合不同的 Linux syscall 调用约定

命令行.S

#include <sys/syscall.h>

    .global _start
_start:
    /* Cause a breakpoint trap */
    int $0x03

    /* exit_group(0) */
    mov $SYS_exit_group, %rax
    mov $0, %rdi
    syscall

命令行.gdb

set confirm off
file cmdline
run
printf "argc: %d\n", *(int*)$rsp
printf "argv[0]: %s\n",  ((char**)($rsp + 8))[0]
quit

正则 C 程序如何获取 argc 和 argv

您可以_start从常规 C 程序中反汇编以查看它如何从堆栈中获取argc并argv在调用时传递它们__libc_start_main。以/bin/true我的 x86-64 机器上的程序为例：

$ gdb -q /bin/true
Reading symbols from /usr/bin/true...Reading symbols from /usr/lib/debug/usr/bin/true.debug...done.
done.
(gdb) disassemble _start
Dump of assembler code for function _start:
   0x0000000000401580 <+0>: xor    %ebp,%ebp
   0x0000000000401582 <+2>: mov    %rdx,%r9
   0x0000000000401585 <+5>: pop    %rsi
   0x0000000000401586 <+6>: mov    %rsp,%rdx
   0x0000000000401589 <+9>: and    $0xfffffffffffffff0,%rsp
   0x000000000040158d <+13>:    push   %rax
   0x000000000040158e <+14>:    push   %rsp
   0x000000000040158f <+15>:    mov    $0x404040,%r8
   0x0000000000401596 <+22>:    mov    $0x403fb0,%rcx
   0x000000000040159d <+29>:    mov    $0x4014c0,%rdi
   0x00000000004015a4 <+36>:    callq  0x401310 <__libc_start_main@plt>
   0x00000000004015a9 <+41>:    hlt    
   0x00000000004015aa <+42>:    xchg   %ax,%ax
   0x00000000004015ac <+44>:    nopl   0x0(%rax)

前三个参数__libc_start_main()是：

  1. RDI：指向的指针main()
  2. RSI : argc，您可以看到它是如何从堆栈中弹出的第一件事
  3. RDX : argv, RSP的值argc被弹出。（ubp_av在 GLIBC 源中）

x86 _start非常相似：

Dump of assembler code for function _start:
   0x0804842c <+0>: xor    %ebp,%ebp
   0x0804842e <+2>: pop    %esi
   0x0804842f <+3>: mov    %esp,%ecx
   0x08048431 <+5>: and    $0xfffffff0,%esp
   0x08048434 <+8>: push   %eax
   0x08048435 <+9>: push   %esp
   0x08048436 <+10>:    push   %edx
   0x08048437 <+11>:    push   $0x80485e0
   0x0804843c <+16>:    push   $0x8048570
   0x08048441 <+21>:    push   %ecx
   0x08048442 <+22>:    push   %esi
   0x08048443 <+23>:    push   $0x80483d0
   0x08048448 <+28>:    call   0x80483b0 <__libc_start_main@plt>
   0x0804844d <+33>:    hlt    
   0x0804844e <+34>:    xchg   %ax,%ax
End of assembler dump.
于 2013-05-23T20:06:48.783 回答