sql - oracle关联数组存在case语句导致编译失败

Question

这是一个假设的例子。实际问题涉及根据值更新各种列，如果它们存在于关联数组中。以下抛出 ORA-06550 和 ORA-01747。请帮助修复错误。

declare
   type MONTH_TYPE is table of varchar2(20) index by binary_integer;

   month_table   MONTH_TYPE;
   mon varchar2(20);
 begin
   month_table(1) := 'Jan';
   month_table(2) := 'Feb';

   select case when month_table.exists(1) then 'found' else 'not found' end into mon from dual;
 end;

Answer 1

不能exists从 SQL 语句调用 PL/SQL 函数。如果需要，可以引用集合中的值：

declare
   type MONTH_TYPE is table of varchar2(20) index by binary_integer;
   month_table   MONTH_TYPE;
   mon varchar2(20);
 begin
   month_table(1) := 'Jan';
   month_table(2) := 'Feb';
   select case when month_table(1)='Jan' then 'found' else 'not found' end
        into mon from dual;
end;

或者您可以exists在 PL/SQL 中使用：

declare
   type MONTH_TYPE is table of varchar2(20) index by binary_integer;

   month_table   MONTH_TYPE;
   mon varchar2(20);
 begin
   month_table(1) := 'Jan';
   month_table(2) := 'Feb';

   mon := case when month_table.exists(1) then 'found' else 'not found' end;
end;

从您的评论看来，数据库类型可能是要走的路：

SQL> create type MONTH_TYPE is table of varchar2(20);

然后你可以在你的 SQL 中选择：

declare
   month_table   MONTH_TYPE := MONTH_TYPE();
   mon varchar2(20);
 begin
   month_table.extend;
   month_table(1) := 'Jan';
   month_table.extend;
   month_table(2) := 'Feb';

   update some_table
   set x = 1
   where month in (select column_value from table(month_table));
end;