0

此功能检查所有员工的工资是否在正确的最高和最低工资范围之间。我想更新它，以便它返回工资超出范围的员工 ID ?? 我尝试定义一个集合，但它一直给我错误。有任何想法吗 ？？

create or replace function min_max return number as
cursor job_cur is
    select job_id, min_salary, max_salary from jobs;
cursor emp_cur(p_job_id jobs.job_id%type) is
    select employee_id, salary from employees where job_id = p_job_id;
Type id_table is table of number index by binary_integer;
return_id id_table;
i number := 1;
begin
for job_rec in job_cur loop
    for emp_rec in emp_cur(job_rec.job_id) loop
        if (emp_rec.salary > job_rec.max_salary)
            or (emp_rec.salary < job_rec.min_salary) then
            --return 0;
            return_id(i).emlpoyee_id := emp_rec.employee_id; // error here
            i := i+1;
        end if;
    end loop;
end loop;
--return 1;
return return_id;  // error here
end min_max;

这是更新的代码，但它不起作用。错误：错误（15,17）：PL/SQL：语句被忽略。错误（15,30）：PLS-00487：对变量“NUMBER”的引用无效。错误（21,5）：PL/SQL：语句被忽略。错误（21,12）：PLS-00382：表达式类型错误。

4

1 回答 1

0

如果在函数外部定义类型，函数可以返回一个集合。另外，不要循环两个游标。如果可以，请始终将 SQL 操作作为一组进行。这样，您将获得更好的性能。

只要员工数量不太大，这很有效：

CREATE TYPE id_table AS TABLE OF NUMBER;

CREATE OR REPLACE FUNCTION min_max RETURN id_table AS
  l_emp_list id_table;
BEGIN
  SELECT e.employee_id 
    BULK COLLECT INTO l_emp_list
    FROM employees e 
   INNER JOIN jobs j ON j.job_id = e.job_id
   WHERE e.salary NOT BETWEEN j.min_salary AND j.max_salary;

  RETURN l_emp_list;
END;

出于某种原因，SQLFiddle 给了我一个错误，但这在我的数据库中有效。

于 2013-05-23T00:31:47.273 回答