0

如何通过运行 .bat 文件获取驱动器总空间和可用空间。在 powershell 脚本中是可能的。但我不应该使用电源外壳。在基本的脚本编程中，我需要得到它。我试过下面的代码，但它没有给出正确的结果

fsutil volume diskfree C:\>temp.txt
FOR /F "Tokens=* skip=1 delims= " %%A IN (temp.txt) DO echo %%A>>temp2.txt
SORT /+32 temp2.txt /O temp3.txt
FOR /F "tokens=5 Delims=: " %%A IN (temp3.txt) DO ECHO %%A>temp4.txt
FOR /f "tokens=1 Delims= " %%A IN (temp4.txt) DO SET a=%%A
set /a b=%a:~0,-10%
set /a c=b*1024
PAUSE
DEL temp.txt
DEL temp1.txt
DEL temp2.txt
DEL temp3.txt
DEL temp4.txt
CLS
ECHO %b% GB (%c% MB)
PAUSE
4

2 回答 2

3

离开 Foxidrive 的回答，我让它枚举所有磁盘驱动器并按照您在脚本中指定的方式输出大小

@echo off
setlocal enabledelayedexpansion

for /f "tokens=1" %%d in (
 'wmic logicaldisk where drivetype^=3 get deviceid ^| find ":"') do ( 
    for /f "skip=1 tokens=1,* delims=:" %%a in ('fsutil volume diskfree %%d') do (
        Call :ConvertBytes %%b GB Gigs
        Call :ConvertBytes %%b MB Megs
        echo %%d - %%a: !Gigs! GB (^!Megs! MB^) >> output.txt
    )
)       
goto :eof


:ConvertBytes bytes unit ret
setlocal
if "%~2" EQU "KB" set val=/1024
if "%~2" EQU "MB" set val=/1024/1024
if "%~2" EQU "GB" set val=/1024/1024/1024
> %temp%\tmp.vbs echo wsh.echo FormatNumber(eval(%~1%val%),0)
for /f "delims=" %%a in ( 
  'cscript //nologo %temp%\tmp.vbs' 
) do endlocal & set %~3=%%a
del %temp%\tmp.vbs
于 2013-05-22T15:52:17.003 回答
1

这在这里使用您的工具有效。我可能误解了-您没有说要计算 GB 等。

@echo off
for /f "skip=1 tokens=1,* delims=:" %%a in ('fsutil volume diskfree c:') do echo %%a - %%b
pause
于 2013-05-22T12:59:28.053 回答