c# - 日期字段中具有可为空值的存储过程

Question

在此存储过程中，在 where 条件下，如果 @startDate 和 @EndDate 值为空，那么如何使用 COALESCE 处理它。

CREATE PROCEDURE  dbo.SP_ManageLeaveSearch

  @StartDate datetime,
  @EndDate datetime,

  @UserName CHAR(100), 
  @MarketID INT 

AS
BEGIN
    SELECT d1.UserName,c1.HouseName,c.StartDate,c.EndDate
        FROM  table1   c    
        Inner  JOIN table2  d1 ON c.UserID = d1.UserID


WHERE 
     (

        (
            (@StartDate BETWEEN StartDate AND EndDate)
            OR 
            (@EndDate BETWEEN StartDate AND EndDate) 
            OR
                (
                (@StartDate <= Startdate AND @EndDate>=EndDate)
                )
        )  
        AND
        (

             d1.UserName = COALESCE(@UserName, d1.UserName) 
        ) 

)

 END

提前谢谢。

Answer 1

这应该适合你：

CREATE PROCEDURE  dbo.ManageLeaveSearch

  @StartDate datetime = NULL,
  @EndDate datetime = NULL,

  @UserName CHAR(100) = NULL, 
  @MarketID INT 

AS
BEGIN
    SELECT d1.UserName,c1.HouseName,c.StartDate,c.EndDate
        FROM  table1   c    
        Inner  JOIN table2  d1 ON c.UserID = d1.UserID


WHERE 
     COALESCE(@StartDate,StartDate) <= EndDate AND
     StartDate <= COALESCE(@EndDate,EndDate) AND
     d1.UserName = COALESCE(@UserName, d1.UserName) 

 END

笔记：

• 不要使用前缀命名存储过程sp_- 它是为 Microsoft 的系统过程保留的。
• 我已经使用更简单的条件来确定是否存在重叠。如果范围 1 在范围 2 结束之前开始，并且范围 2 在范围 1 结束之前开始，则两个范围之间存在重叠。
• 我已经为那些应该可以为空的参数指定了默认值。

Answer 2

试试这个——

CREATE PROCEDURE dbo.usp_ManageLeaveSearch

  @StartDate DATETIME,
  @EndDate DATETIME,

  @UserName CHAR(100), 
  @MarketID INT 

AS BEGIN

    SELECT 
          d1.UserName
        , c.HouseName
        , c.StartDate
        , c.EndDate
    FROM dbo.table1 c    
    JOIN dbo.table2 d1 ON c.UserID = d1.UserID
    WHERE d1.UserName = ISNULL(@UserName, d1.UserName) 
        AND (
              ISNULL(@StartDate, StartDate) BETWEEN StartDate AND EndDate
            OR 
              ISNULL(@EndDate, EndDate) BETWEEN StartDate AND EndDate
        )

 END

Answer 3

你的事情太复杂了。这应该对您有用，并且就像我所知道的那样简单的查询。我更喜欢这种语法，因为在我的大多数用例中， ...OR @UserName IS NULL 可以在查询执行之前从查询中删除，从而实现非常简单、快速的执行。

CREATE PROCEDURE  dbo.SP_ManageLeaveSearch

  @StartDate datetime,
  @EndDate datetime,

  @UserName CHAR(100), 
  @MarketID INT 

AS
BEGIN
SELECT d1.UserName,c1.HouseName,c.StartDate,c.EndDate
FROM table1 c    
JOIN table2 d1
    ON c.UserID = d1.UserID
WHERE (@StartDate<=EndDate OR @StartDate IS NULL)
AND (@EndDate>=StartDate OR @EndDate IS NULL)
AND (d1.UserName = @UserName OR @UserName IS NULL)
END